正在进行的聚合函数 OpenEdge 10.2B

Question

我的任务是将存储过程从 SQL Server 转换为 Progress 代码。

一切都很顺利，但我昨天遇到了一个谜。

我们如何在OpenEdge V10.2B 中进行Min、Max、Avg 等聚合函数？

这里是一个 SQL Server 场景：

WITH Inventory (ItemNo, Quantity)
AS
(
          SELECT 'ItemA', 100
    UNION SELECT 'ItemA', 200
    UNION SELECT 'ItemC', 300
    UNION SELECT 'ItemB', 400
    UNION SELECT 'ItemA', 500
    UNION SELECT 'ItemB', 600
)
SELECT
    ItemNo
    ,MIN(Quantity)   AS Min1
    ,MAX(Quantity)   AS Max1
    ,AVG(Quantity)   AS Avg1
    ,SUM(Quantity)   AS Sum1
    ,COUNT(Quantity) AS Count1
FROM Inventory
GROUP BY
    ItemNo

结果是：

ItemNo   Min1    Max1    Avg1    Sum1     Count1
ItemA    100     500     266     800      3
ItemB    400     600     500     1000     2
ItemC    300     300     300     300      1

谢谢你， 祝你有美好的一天！ 塞巴斯蒂安

Answer 1

好的，我喜欢挑战。所以，这里是使用 Progress 的内置聚合函数的解决方案。

首先，一些家务：设置临时表并填充它：

DEFINE TEMP-TABLE ttTest
    FIELD ItemNo AS CHARACTER
    FIELD Quantity AS INTEGER
    INDEX ItemNo ItemNo.

RUN ipCreateTest("ItemA",100).
RUN ipCreateTest("ItemA",200).
RUN ipCreateTest("ItemC",300).
RUN ipCreateTest("ItemB",400).
RUN ipCreateTest("ItemA",500).
RUN ipCreateTest("ItemB",600).

PROCEDURE ipCreateTest:
DEFINE INPUT  PARAMETER pcItem AS CHARACTER   NO-UNDO.
DEFINE INPUT  PARAMETER piQty  AS INTEGER     NO-UNDO.

CREATE ttTest.
ASSIGN
    ttTest.ItemNo = pcItem
    ttTest.Quantity = piQty
    .
END.

然后，实际的报告部分：

FOR EACH ttTest
    NO-LOCK
    BREAK BY ttTest.ItemNo:
    ACCUMULATE ttTest.Quantity
        (MINIMUM MAXIMUM AVERAGE TOTAL COUNT BY ttTest.Itemno).
    IF LAST-OF(ttTest.itemNo) THEN DO:
        DISPLAY
            ttTest.ItemNo
            ACCUM MINIMUM BY ttTest.ItemNo ttTest.Quantity
                COLUMN-LABEL "Min1"
            ACCUM MAXIMUM BY ttTest.ItemNo ttTest.Quantity
                COLUMN-LABEL "Max1"
            ACCUM AVERAGE BY ttTest.ItemNo ttTest.Quantity
                COLUMN-LABEL "Avg1"
            ACCUM TOTAL BY ttTest.ItemNo ttTest.Quantity
                COLUMN-LABEL "Sum1"
            ACCUM COUNT BY ttTest.ItemNo ttTest.Quantity
                COLUMN-LABEL "Count1"
            .
    END.
END.

内置函数有效，但语法非常违反直觉恕我直言。我会采用 Tim 的解决方案，主要是因为我可能会在使用 ACCUM 和 ACCUMULATE 进行第二次迭代时完成该策略的问题，弄清楚括号的位置...... :)

Answer 2

这将为您提供您正在寻找的 ItemNo 值：

    DEFINE VARIABLE iMin    AS INTEGER      NO-UNDO.
    DEFINE VARIABLE iMax    AS INTEGER      NO-UNDO.
    DEFINE VARIABLE iTotal  AS INTEGER      NO-UNDO.
    DEFINE VARIABLE iCount  AS INTEGER      NO-UNDO.


    FOR EACH Inventory
        NO-LOCK
        BREAK BY Inventory.itemno
        :

        IF FIRST-OF(Inventory.itemno) THEN
            ASSIGN
                iMin    = 99999999
                iMax    = -99999999
                iTotal  = 0
                iCount  = 0
                .

        ASSIGN
            iMin    = MIN(iMin, inventory.quantity)
            iMax    = MAX(iMax, inventory.quantity)
            iTotal  = iTotal + inventory.quantity 
            iCount  = iCount + 1
            .

        IF LAST-OF(Inventory.itemno) THEN
            DISPLAY
                    Inventory.itemno
                    iMin
                    iMax
                    iTotal / iCount
                    iTotal
                    iCount
                WITH FRAME f-show
                    DOWN
                    .

    END.