从旧 CUDA 版本更新项目

Question

在我较早的 CUDA 项目中，我有全局变量：

__device__ uint8_t dev_intersect
__constant__ uint8_t dev_flags

...并以这种方式使用它们：

cudaGetSymbolAddress((void**)&ptr_dev_intersect,"dev_intersect")
cudaMemcpyToSymbol("dev_flags",&flags,sizeof(flags))

现在，由于 CUDA 5.0（和更高版本）必须直接传递符号（不带字符串），所以我这样定义全局变量：

__device__ uint8_t *dev_intersect
__constant__ uint8_t *dev_flags

...并以这种方式调用函数：

cudaGetSymbolAddress((void**)&ptr_dev_intersect,dev_intersect)
cudaMemcpyToSymbol(dev_flags,&flags,sizeof(flags))

到目前为止，我做得对吗？我在问你，因为当我更新代码时，我开始收到其他错误，这让我有点怀疑。谢谢你的帮助。

Answer 1

从 POD 变量切换到指针可能不是您想要的。

如果您没有在代码的其他地方进行更改以解决该差异，我预计会出现问题。

要更新您的 cuda 函数调用，请保持您的变量不变：

__device__ uint8_t dev_intersect;
__constant__ uint8_t dev_flags;

只需从使用这些变量的 cuda API 函数中删除引号：

cudaGetSymbolAddress((void**)&ptr_dev_intersect,dev_intersect);
cudaMemcpyToSymbol(dev_flags,&flags,sizeof(flags));

这是一个完整的工作示例：

$ cat t524.cu
#include <stdio.h>
typedef unsigned char uint8_t;

__device__ uint8_t dev_intersect;
__constant__ uint8_t dev_flags;

__global__ void mykernel(uint8_t *d1_ptr){

  printf("data 1 = %c\n", *d1_ptr);
  printf("dev_flags = %c\n", dev_flags);

}

int main(){

  uint8_t *ptr_dev_intersect;
  uint8_t flags = 'X';
  uint8_t dev_intersect_data = 'Y';

  cudaGetSymbolAddress((void**)&ptr_dev_intersect,dev_intersect);
  cudaMemcpyToSymbol(dev_flags,&flags,sizeof(flags));
  cudaMemcpyToSymbol(dev_intersect,&dev_intersect_data,sizeof(dev_intersect_data));

  mykernel<<<1,1>>>(ptr_dev_intersect);
  cudaDeviceSynchronize();
  return 0;
}

$ nvcc -arch=sm_20 -o t524 t524.cu
$ cuda-memcheck ./t524
========= CUDA-MEMCHECK
data 1 = Y
dev_flags = X
========= ERROR SUMMARY: 0 errors
$