不同类型的类型类约束

Question

我一直在摆弄 Haskell 中列表的通用类型类。

class HasEmpty a where
  empty :: a
  isEmpty :: a -> Bool

class HasEmpty (l a) => List l where
  cons :: a -> l a -> l a
  uncons :: l a -> (a, l a)

为了让您了解它的工作原理，以下是[] 的实例：

instance HasEmpty [a] where
  empty = []
  isEmpty [] = True
  isEmpty _  = False

instance List [] where
  cons = (:)
  uncons (x:xs) = (x,xs)

但是，这会引发错误：

Not in scope: type variable 'a'

这是由约束HasEmpty (l a) 引起的。我对这个特定的例子并不是非常感兴趣，但我对这个概念很感兴趣。 HasEmpty 是 * 类型的类，而 List 是 * -> * 类型的类。 我是否可以创建与它所约束的类型类不同类型的类型类约束？

Answer 1

在任何情况下，您都可以使用多参数类型类来表达底层逻辑（事实上它是在ListLike 中完成的）：

{-# LANGUAGE MultiParamTypeClasses, FlexibleInstances #-}

class HasEmpty a where
  empty :: a
  isEmpty :: a -> Bool

class HasEmpty (l a) => List l a where
  cons :: a -> l a -> l a
  uncons :: l a -> (a, l a)


instance HasEmpty [a] where
  empty = []
  isEmpty [] = True
  isEmpty _  = False

instance List [] a where
  cons = (:)
  uncons (x:xs) = (x,xs)

或者更优雅地通过类型族：

{-# LANGUAGE TypeFamilies #-}

class HasEmpty a where
  empty :: a
  isEmpty :: a -> Bool


class HasEmpty a => List a where
  type Elem a :: *
  cons :: Elem a -> a -> a
  uncons :: a -> (Elem a, a)


instance HasEmpty [a] where
  empty = []
  isEmpty [] = True
  isEmpty _  = False


instance List [a] where
  type Elem [a] = a
  cons = (:)
  uncons (x:xs) = (x,xs)

Answer 2

当然可以。例如。这对于相同的两个类都可以正常工作：

class HasEmpty (l ()) => List l where
  cons :: a -> l a -> l a
  uncons :: l a -> (a, l a)

或（List1 :: (* -> *) -> * -> *）

class HasEmpty1 (l a) => List1 l a where
  cons :: a -> l a -> l a
  uncons :: l a -> (a, l a)

你不能做的是在约束中添加新变量。