使用 Excel VBA 激活选择值的组合框操作

Question

我正在显示一个组合框，其中包含工作簿的所有工作表名称。 如果我选择一个值，我希望 Excel 跳转到选定的工作表。

我尝试在此代码上执行激活代码行，但它似乎不起作用。

Private Sub ComboBox1_Change()
Dim Sh As Worksheet
Dim sVal As String

With ComboBox1
sVal = .Text
.Clear
For Each Sh In ActiveWorkbook.Sheets
If Sh.Name <> "Inputs" Then
.AddItem Sh.Name
End If
Next
.Value = sVal
End With
End Sub

Answer 1

您要在Change Event 中添加工作表名称？这将重新触发 Change Event。我建议在 UserForm_Initialize 事件中填充它。

这是你正在尝试的吗？

Dim Sh As Worksheet

Private Sub UserForm_Initialize()
    For Each Sh In ThisWorkbook.Sheets
        If Sh.Name <> "Inputs" Then
            ComboBox1.AddItem Sh.Name
        End If
    Next

    ComboBox1.Style = fmStyleDropDownList
End Sub

Private Sub ComboBox1_Change()
    With ThisWorkbook.Sheets(ComboBox1.Text)
        .Visible = xlSheetVisible
        .Activate
    End With
End Sub

我的假设

您在用户窗体上有这个组合框。如果没有，则对代码进行相关更改。但主旨保持不变。

评论跟进

在工作表上添加一个按钮。将其命名为 Refresh 并使用此代码

Dim Sh As Worksheet

Private Sub CommandButton1_Click()
    ComboBox1.Clear

    For Each Sh In ThisWorkbook.Sheets
        If Sh.Name <> "Inputs" Then
            ComboBox1.AddItem Sh.Name
        End If
    Next

    ComboBox1.Style = fmStyleDropDownList
End Sub

Private Sub ComboBox1_Change()
    With ThisWorkbook.Sheets(ComboBox1.Text)
        .Visible = xlSheetVisible
        .Activate
    End With
End Sub