需要 VBscript 对象 800A01A8

Question

请帮忙。无法使此代码工作。它需要一个对象。不知道如何解决这个问题。我在我的脚本上没有看到拼写错误。我正在尝试检查我的 PC 中是否有对 https://www.test.com 开放的 Internet Explorer。学校项目急需。提前致谢

Option Explicit
Dim objShell, objShellWindows, i, objIE
Set objShell = CreateObject("Shell.Application")
Set objShellWindows = objShell.Windows

For i = 0 to objShellWindows.Count - 1
    Set objIE = objShellWindows.Item(i)
    strURL = objIE.LocationURL
    If InStr(strURL, "https://www.test.com/")Then
        blnFound = True
    End If
Next

Answer 1

下面的代码会检查 IE 中加载的所有 URL，
请注意，当sURL 在.LocationURL 内部时，bFound 为 True，而不是以开头。修改以满足您的需要。

Option Explicit

Const sURL = "https://www.test.com/"
Dim oShell, oWindow, oIE, bFound
Set oShell = CreateObject("Shell.Application")
bFound = False
For Each oWindow In oShell.Windows
    If InStr(1,oWindow.Fullname,"iexplore.exe",vbTextCompare) > 0 Then
        Set oIE = oWindow
        With oIE
            'Wscript.Echo .LocationURL
            bFound = (InStr(1,.LocationURL,sURL,vbTextCompare) > 0)
            If bFound Then Exit For
        End With
        Set oIE = Nothing
    End If
Next
If bFound Then
    Wscript.Echo sURL & " is loaded"
Else
    Wscript.Echo sURL & " is NOT loaded"
End If
Set oShell = Nothing