vb.net：使用泛型时调用构造函数

Question

我不确定这是否可能。

我有许多实现接口 IBar 的不同类，并且有接受几个值的构造函数。与其创建一堆几乎相同的方法，是否可以有一个通用方法来创建适当的构造函数？

private function GetFoo(Of T)(byval p1, byval p2) as List(Of IBar)
  dim list as new List(Of IBar)

  dim foo as T

  ' a loop here for different values of x
     foo = new T(x,p1) 
     list.Add(foo)
  ' end of loop
  return list
end function

我明白了：

'New' cannot be used on a type parameter that does not have a 'New' constraint. 

Answer 1

不幸的是，.NET 泛型仅允许您将泛型类型约束为具有无参数构造函数，然后您可以使用New T() 调用它...您不能指定一组特定的参数。

如果你不介意让你的类型可变，你可以创建一个接口，其中包含一个带有相关参数的方法，让你的所有类型都实现这个接口，然后约束要实现的类型该方法并具有无参数构造函数，但并不理想。

另一种选择是传入一个适当的Func，它接受x 和p1，每次都返回一个新的T。这在 C# 中肯定很容易使用 - 在 VB IIRC 中不是相当那么容易，但值得考虑。

Answer 2

扩展 Jon Skeet 的答案，这是使用 Func 参数的可能解决方案：

Private Function GetFoo(Of T As IBar)(ByVal p1 As Object, ByVal p2 As Object, ctor As Func(Of Integer, Object, T)) As List(Of IBar)
    Dim list As New List(Of IBar)
    Dim foo As T
    For x = 1 To 10
        foo = ctor(x, p1)
        list.Add(foo)
    Next
    Return list
End Function

用法类似于

    GetFoo(1, 2, Function(i, o) New BarImpl(i, o))

Answer 3

即使在通用约束中没有指定构造函数，也可以调用它。请参阅下面的示例。

    'This base class has no constructor except the default empty one
Public Class MyBaseClass

End Class

'this class inhetits MyBaseType, but it also implements a non empty constructor
Public Class MySpecializedClass
    Inherits MyBaseClass
    Public Sub New(argument As String)

    End Sub
End Class

Public Function CreateObject(Of ClassType As MyBaseClass)(argument As String) As ClassType
    'First, get the item type:
    Dim itemType As Type = GetType(ClassType)
    'Now we can use the desired constructor:
    Dim constructor As ConstructorInfo = itemType.GetConstructor(New Type() {GetType(String)})
    If constructor Is Nothing Then
        Throw New InvalidConstraintException("Constructor ""New(String)"" not found.")
    Else
        Dim result As ClassType = constructor.Invoke(New Object() {argument})
        Return result
    End If
End Function

Public Sub RunTest()
    Try
        Console.WriteLine("+----------------------------------------------------+")
        Console.WriteLine("Trying to create a instance of MyBaseClass")
        Console.WriteLine("+----------------------------------------------------+")
        Dim myobject As MyBaseClass = CreateObject(Of MyBaseClass)("string value")
        Console.WriteLine(myobject)
        Console.WriteLine("Instance of MyBaseClass created")
    Catch ex As Exception
        Console.WriteLine(ex)
    End Try
    Try
        Console.WriteLine("+----------------------------------------------------+")
        Console.WriteLine("Trying to create a instance of MySpecializedClass")
        Console.WriteLine("+----------------------------------------------------+")
        Dim myobject As MyBaseClass = CreateObject(Of MySpecializedClass)("string value")
        Console.WriteLine(myobject)
        Console.WriteLine("Instance of MySpecializedClass created")
    Catch ex As Exception
        Console.WriteLine(ex)
    End Try
End Sub

Answer 4

这是我的答案。

Public CreateObject(Of T)() As T
    Dim newObj = Activator.CreateInstance(GetType(T), YourParameterHere)
    Return newObj
End Function

这将为您提供新对象。您可以将任何参数传递给此函数。