VBA 暗淡 ws 作为工作表（不是工作表）

Question

好吧，我知道我可以做到：

Dim ws as worksheet
Set ws = thisworkbook.worksheets("Sheet1")

然后用ws 工作表对象做我喜欢的事情

我也知道我可以Dim wss as worksheets 并且使用worksheets("Sheet1") 返回工作表对象。那么为什么以下方法不起作用？

Dim wss as worksheets
Dim ws as worksheet
Set wss = thisworkbook.worksheets
Set ws = wss("Sheet1")

我也试过了：

Dim wss as worksheets
Dim ws as worksheet
Set ws = thisworkbook.wss("Sheet1")

但后者看起来就像我正在尝试重命名/缩短“工作表”，这似乎完全错误。我正在尝试将工作簿的工作表放入一个名为 wss 的工作表对象中。这更多的是试图理解 heirachy，但出于功能目的，我试图让 wss 包含工作簿 x 中的所有工作表，所以我可以只做 ws = wss(1) 而不是说 set ws = wb.worksheets(1)

这是可能的还是我误解了工作表/工作表的关系？

Answer 1

您必须将wss 声明为Sheets 对象

Dim wss As Sheets
Dim ws As Worksheet

Set wss = ThisWorkbook.Worksheets
Set ws = wss("Sheet1")

这是因为Workbook 对象的Worksheets 属性返回一个Sheets 集合，即包含工作簿的Worksheets 和Charts 对象的集合

如果您只需要 Workbook Worksheets（而不是 Charts）的集合来调用 ws = wss(1) 或类似的方法，那么您可以对 Collection 对象采用以下解决方法

Option Explicit

Sub main()
    Dim wss As Collection
    Dim ws As Worksheet

    Set wss = GetWorkSheets
    Set ws = wss("Sheet1")
    Set ws = wss(1)
End Sub

Function GetWorkSheets() As Collection
    Dim wss As New Collection
    Dim ws As Worksheet

    For Each ws In ThisWorkbook.Worksheets
        wss.add ws, ws.Name
    Next ws
    Set GetWorkSheets = wss
End Function