如果从 Excel 中打开文件，则代码仅在 Excel 2007 上运行

Question

我有一些相对简单的代码循环遍历文件夹中的多个文件，打开每个文件并将一系列数据复制到一个新的工作表中。我使用 Excel 2013 编写了代码。一些用户的盒子上有 2007。如果 2007 用户从 Excel 中打开文件（即文件打开，然后导航到目录），它运行良好。如果 2007 用户从 Windows 资源管理器打开文件，所有宏都会运行，除了我在循环中使用的文件名变量“myFile”始终为 EMPTY。就像它不会导航到目录一样。我没有收到任何错误，它只是执行代码并一直到循环的结尾（当“myFile”为空时停止）——然后继续执行下一个宏。使用 Excel 2013，无论程序如何打开，程序都能正常运行。我认为我的答案可能已包含在此线程中：Excel Workbook Open Event macro doesn't always run 但问答似乎并不直接适用于我的问题，因为宏实际运行。似乎只是导航到文件位置不起作用。这是运行循环的代码的 sn-p：

    Dim myfile As String
Dim wb As Workbook
Dim ws As Worksheet
Dim DataBlock As Range

'Optimize Macro Speed
    Application.ScreenUpdating = False
    Application.EnableEvents = False
    Application.Calculation = xlCalculationManual

Set wb = Workbooks("ComboFile.xlsm")
Set ws = wb.Sheets("Sheet1")    'change desired sheet

ChDir "r:\BSI\Sys9000"
myfile = Dir("*.xlsx")

Do Until myfile = ""
    Workbooks.Open Filename:=myfile
    Set DataBlock = Range("A2").CurrentRegion
    DataBlock.Copy ws.Cells(ws.Rows.Count, "A").End(xlUp).Offset(1)
    Windows(myfile).Close
    myfile = Dir
Loop

'Reset Macro Optimization Settings
    Application.ScreenUpdating = True
    Application.EnableEvents = True
    Application.Calculation = xlCalculationAutomatic

欢迎提出任何建议。谢谢你。

Answer 1

我建议你替换这个：

ChDir "r:\BSI\Sys9000"
myfile = Dir("*.xlsx")

只有这个：

myfile = Dir("r:\BSI\Sys9000\*.xlsx")

ChDir 不会更改驱动器，因此如果当前目录不在 R 驱动器上，代码将失败。

您还需要更改此设置：

Workbooks.Open Filename:=myfile

包含路径：

Workbooks.Open Filename:="r:\BSI\Sys9000\" & myfile