匹配行的最大值和最小值答案

【问题标题】：max and min value of matching lines匹配行的最大值和最小值
【发布时间】：2014-10-07 22:40:08
【问题描述】：

我想计算文件中匹配行的最小值和最大值：

我有：

xxx 5
xxx 0  
xxx 10  
yyy 1  
yyy 5  
yyy 10

我想输出：

xxx 0 10
yyy 1 10

xxx 和 yyy 匹配的最小值和最大值。

我的代码是：

awk '{if(min==""){min=max=$2}
      if($2>max) {max=$2}
      if($2<min) {min=$2}
      n[$1]++}
      END {for (l in n) {print l "\t" min[l] }}' inputfile

非常感谢您的帮助。

【问题讨论】：

那么你的错误是什么？甚至有错误吗？

标签： awk max matching min lines

【解决方案1】：

为此你需要数组：

awk '!($1 in min) {min[$1]=$2; max[$1]=$2}
     {max[$1]=(max[$1]<$2?$2:max[$1])
      min[$1]=(min[$1]>$2?$2:min[$1])}
      END { for (i in max) print i, min[i], max[i]}' file

说明

max[] 包含每个值的最大值。这同样适用于min[]。

!($1 in min) {min[$1]=$2; max[$1]=$2} 如果当前字段没有min，则初始化它们。
max[$1]=(max[$1]<$2?$2:max[$1]) 如果当前第二个字段大于第一列对应的最大值，则替换。
min[$1]=(min[$1]>$2?$2:min[$1]) 与最小值相同。
END { for (i in max) print i, min[i], max[i]} 循环遍历结果并打印出来。

测试

$ awk '!($1 in min) {min[$1]=$2; max[$1]=$2} {max[$1]=(max[$1]<$2?$2:max[$1]); min[$1]=(min[$1]>$2?$2:min[$1])} END { for (i in max) print i, min[i], max[i]}' a
yyy 1 10
xxx 0 10

我们需要在读取第一行时定义最小值和最大值！

$ cat a
x -1
x 0
y 1
x -3
$ awk '!($1 in min) {min[$1]=$2; max[$1]=$2} {max[$1]=(max[$1]<$2?$2:max[$1]); min[$1]=(min[$1]>$2?$2:min[$1])} END { for (i in max) print i, min[i], max[i]}' a
x -3 0
y 1 1

【讨论】：

如果内存受限，也可以使用getline。
我认为这里没有必要使用getline，@Jidder，你将如何实现它？有了数组就足够了。 Ed Morton 有一篇很好的论文在谈论它，现在找不到了。
请注意，我更新了我的第一个答案，它有点错误。
没问题，@Jidder！重新思考我们做什么和如何做总是好的。感谢您的评论:)
@fedorqui 是的，我很抱歉我的错。如果我的值为零，第一个代码将失败。新的更新代码与 0 值完美配合（零是我文件中的最低值）。非常感谢您的时间和帮助！我学到了一些新东西！