Excel VBA - 无法选择多个不连续的列范围

Question

我正在尝试将一些不连续的列（例如 A 列、C 列、E 列）复制到一个动态数组中。但是，当使用 VBA Application.Union 方法时，似乎只复制了连续的范围，留下了不连续的范围。

我已尝试复制连续列（A、B、C、D、E），结果按预期工作，但非连续列（A、C、E）没有。

有人可以帮助我吗？谢谢。

Sub TestFunction()

    Dim TempArray() As Variant
    Dim rngUnion As Range
    With ThisWorkbook.Worksheets(2)
        Set rngUnion = Application.Union(.Range("A1:A10"), .Range("C1:C10"), .Range("E1:E10"))
    End With

    TempArray = rngUnion
End Sub

Answer 1

蒂姆·威廉姆斯已经回答了您的问题。我只是想演示一种从多个非连续范围创建数组的酷方法。这项工作的关键是所有范围都有 1 列和相同的行数。

getArrayFromRanges 从传递给它的每个范围中获取值数组，并使用 Transpose 将其从二维数组转换为一维数组。这些 1D Temp 数组中的每一个都被添加到 1D Data 数组中。然后使用转置将数据从一维数组或一维数组转换为二维数组。

Sub TestFunction()
    Dim Data
    With Worksheets(2)
        Data = getArrayFromRanges(.Range("A1:A10"), .Range("C1:C10"), .Range("E1:E10"))
        .Range("A12").Resize(UBound(Data, 1), UBound(Data, 2)) = Data
    End With
End Sub

Function getArrayFromRanges(ParamArray Sources())
    Dim Data, Temp, v
    Dim x As Long
    ReDim Data(UBound(Sources))

    For Each v In Sources
        Temp = Application.Transpose(v)
        Data(x) = Temp
        x = x + 1
    Next

    getArrayFromRanges = Application.Transpose(Data)

End Function

来自Contextures Excel Sample Data的样本数据

Answer 2

你没有提到你对数组做了什么，所以我不确定这是否适合你。但是，为什么不直接使用rngUnion 而不是数组，并根据需要循环遍历其Areas 集合呢？

例如这个函数：

Sub TestFunction2()
    Dim rngUnion As Range
    Dim area As Range
    With ThisWorkbook.Worksheets(2)
        Set rngUnion = Application.Union(.Range("A1:A10"), .Range("C1:C10"), .Range("E1:E10"))
    End With

    For Each area In rngUnion.Areas
        Debug.Print area.Address
    Next area

    Set area = Nothing
    Set rngUnion = Nothing
End Sub

返回这个输出：

$A$1:$A$10
$C$1:$C$10
$E$1:$E$10

如果您确实需要该数组，您可以使用相同的循环将单个 Areas（即 Ranges）添加到数组中。