CUDA：有没有更快的写入全局内存的方法？

Question

我在写一个n体模拟，基本上整个操作是：

-Prepare CUDA memory
 loop {
    -Copy data to CUDA
    -Launch kernel
    -Copy data to host
    -Operations using data (drawing etc.)
 }

我注意到几乎 90% 的时间都花在了将数据写入内核中的全局设备内存上。这是内核：

 __global__ void calculateForcesCuda(float *deviceXpos, float *deviceYpos, float *deviceZpos,
                                    float *deviceXforces, float *deviceYforces, float *deviceZforces,
                                    float *deviceMasses, int particlesNumber) {
     int tid = threadIdx.x + blockIdx.x * blockDim.x;
     if (tid <= particlesNumber) {
         float particleXpos = deviceXpos[tid];
         float particleYpos = deviceYpos[tid];
         float particleZpos = deviceZpos[tid];
         float xForce = 0.0f;
         float yForce = 0.0f;
         float zForce = 0.0f;
         for (int index=0; index<particlesNumber; index++) {
             if (tid != index) {
                 float otherXpos = deviceXpos[index];
                 float otherYpos = deviceYpos[index];
                 float otherZpos = deviceZpos[index];
                 float mass = deviceMasses[index];
                 float distx = particleXpos - otherXpos;
                 float disty = particleYpos - otherYpos;
                 float distz = particleZpos - otherZpos;
                 float distance = sqrt((distx*distx + disty*disty + distz*distz) + 0.01f);
                 xForce += 10.0f * mass / distance * (otherXpos - particleXpos);
                 yForce += 10.0f * mass / distance * (otherYpos - particleYpos);
                 zForce += 10.0f * mass / distance * (otherZpos - particleZpos);
             }
         }
         deviceXforces[tid] += xForce;
         deviceYforces[tid] += yForce;      
         deviceZforces[tid] += zForce;
     }
 }

运行它的设备是 GTX 970。执行时间约为 8.0 秒，但添加这些标志后：-gencode arch=compute_52,code=sm_52 strong>，性能提升到 6.7 秒左右。注释掉写入全局设备内存的代码后：

deviceXforces[tid] += xForce;
deviceYforces[tid] += yForce;      
deviceZforces[tid] += zForce;

... 总执行时间减少到 0.92 秒左右，这意味着写入全局设备内存大约需要 86% 的执行时间。有没有办法提高这些写入的性能？

Answer 1

内存通常是这种计算的瓶颈，即使它没有像您测量的那样占用 90% 的时间。我会建议两件事。

将device...[index] 加载到共享内存中

就目前而言，所有线程都读取相同的deviceXpos[index]、deviceYpos[index]、deviceZpos[index] 和deviceMasses[index]。相反，您可以将它们加载到共享内存中：

static const int blockSize = ....;

__shared__ float shXpos[blockSize];
__shared__ float shYpos[blockSize];
__shared__ float shZpos[blockSize];
__shared__ float shMasses[blockSize];
for (int mainIndex=0; mainIndex<particlesNumber; index+=blockSize) {
    __syncthreads(); //ensure computation from previous iteration has completed
    shXpos[threadIdx.x] = deviceXpos[mainIndex + threadIdx.x];
    shYpos[threadIdx.x] = deviceYpos[mainIndex + threadIdx.x];
    shZpos[threadIdx.x] = deviceZpos[mainIndex + threadIdx.x];
    shMasses[threadIdx.x] = deviceMasses[mainIndex + threadIdx.x];
    __syncthreads(); //ensure all data is read before computation starts
    for (int index=0; index<blockSize; ++index) {
        .... //your computation, using sh....[index] values
    }
}

这应该会减少全局内存读取量，因为每个线程读取不同的数据，而不是全部读取相同的数据。

但是请注意，如果驱动程序正确管理 L1 缓存，此建议可能不会那么有效。试试吧！

每个线程处理超过 1 个（接收）粒子

您可能希望一次计算多个粒子。您可以同时拥有几个 {particleX/Y/Zpos, x/y/zForce}，而不是只有一组 {x/y/zForce}，代表单个粒子接收力。 这样，通过在循环中加载一次源，您可以处理多个接收器。

这可能会显着降低您的内存压力，但同时会增加您的寄存器数量。寄存器太多 - 您将无法启动那么多线程。

检查您的线程已有多少个寄存器，并查阅 CUDA 占用计算器，看看您还能使用多少个。也许将占用率从 1 减少到 0.5 或 0.75，但同时处理更多的粒子会是有益的？您需要进行试验，因为这可能因 GPU 而异。