从 PC 获取唯一的硬件 ID

Question

我尝试从我的 PC 获取硬盘和主板序列号。它在 Windows 7 及更高版本中运行良好

但 CMD 中的相同代码不适用于 Windows XP。它显示 O.E.M 被填充或不返回任何内容

wmic diskdrive get name,serialnumber,model // This is cmd to get serial num

在 Windows XP 中返回序列号错误

wmic baseboard get product,Manufacturer,version,serialnumber // This is cmd to get MotherBoard serialnumber

在 Windows XP 和 Win 8 中，它返回序列号错误，如“由 OEM 填写”

我正在寻找 Best Pc Unique Id ，它可以返回任何操作系统的 id 或序列号，并且应该是唯一的..

请帮帮我

谢谢。

Answer 1

我在网上找到了一个小项目：

• 处理器 ID
• 主板ID
• 卷序列号
• Mac 地址 ID

然后他们通过 MD5 对其进行哈希处理，但它现在已贬值，因此最好的办法是做同样的事情并通过 Sha512

对其进行哈希处理

如果没有自动完成，首先你需要导入和引用：

Imports System.Management
Imports System.Security.Cryptography
Imports System.Text

然后函数获取HWID(HardwareID)

Public Function Get_HWID() As String
    'Information Handler
    Dim hw As New clsComputerInfo
    'Decalre variables
    Dim hdd, cpu, mb, mac As String
    'Get all the values
    cpu = hw.GetProcessorId()
    hdd = hw.GetVolumeSerial("C")
    mb = hw.GetMotherBoardID()
    mac = hw.GetMACAddress()
    'Generate the hash
    Dim hwid As String = GenerateSHA512String(cpu & hdd & mb & mac)
    Return hwid
End Function

生成哈希函数：

Public Shared Function GenerateSHA512String(ByVal inputString) As String
    Dim sha512 As SHA512 = SHA512Managed.Create()
    Dim bytes As Byte() = Encoding.UTF8.GetBytes(inputString)
    Dim hash As Byte() = sha512.ComputeHash(bytes)
    Dim stringBuilder As New StringBuilder()
    For i As Integer = 0 To hash.Length - 1
        stringBuilder.Append(hash(i).ToString("X2"))
    Next
    Return stringBuilder.ToString()
End Function

最后是Class来获取信息：

Public Class clsComputerInfo
    Friend Function GetProcessorId() As String
        Dim strProcessorId As String = String.Empty
        Dim query As New SelectQuery("Win32_processor")
        Dim search As New ManagementObjectSearcher(query)
        Dim info As ManagementObject
        For Each info In search.Get()
            strProcessorId = info("processorId").ToString()
        Next
        Return strProcessorId
    End Function
    Friend Function GetMACAddress() As String
        Dim mc As ManagementClass = New ManagementClass("Win32_NetworkAdapterConfiguration")
        Dim moc As ManagementObjectCollection = mc.GetInstances()
        Dim MACAddress As String = String.Empty
        For Each mo As ManagementObject In moc
            If (MACAddress.Equals(String.Empty)) Then
                If CBool(mo("IPEnabled")) Then MACAddress = mo("MacAddress").ToString()
                mo.Dispose()
            End If
            MACAddress = MACAddress.Replace(":", String.Empty)
        Next
        Return MACAddress
    End Function
    Friend Function GetVolumeSerial(Optional ByVal strDriveLetter As String = "C") As String
        Dim disk As ManagementObject = New ManagementObject(String.Format("win32_logicaldisk.deviceid=""{0}:""", strDriveLetter))
        disk.Get()
        Return disk("VolumeSerialNumber").ToString()
    End Function
    Friend Function GetMotherBoardID() As String
        Dim strMotherBoardID As String = String.Empty
        Dim query As New SelectQuery("Win32_BaseBoard")
        Dim search As New ManagementObjectSearcher(query)
        Dim info As ManagementObject
        For Each info In search.Get()
            strMotherBoardID = info("SerialNumber").ToString()
        Next
        Return strMotherBoardID
    End Function
End Class

我查看了this project的代码

希望这可以帮助您，请记住添加对管理

的引用

更多信息：

用于 HWID 的最常见 ID 是：CPU ID 和 基于 MAC 地址的硬件 ID 和 硬盘序列号

不建议将 HWID 作为许可系统，因为如果用户更改计算机或格式化驱动器等，它不准确且不实用。更建议使用证书系统或更复杂的身份验证。

Answer 2

记住Mac地址和卷序列号是可以更改的。因此，硬件将发生不可预测的变化。
因此，请使用 处理器 和 主板 ID，以便 硬件 ID 永远不会改变。
因此，在此基础上，您可以修改@Mederic 代码如下：

'Get the MotherBoard ID
    Function GetMotherBoardID() As String
        Dim query As New SelectQuery("Win32_BaseBoard")
        Dim search As New ManagementObjectSearcher(query)
        For Each info As ManagementObject In search.Get()
            Return info("SerialNumber").ToString()
        Next
    End Function

'Get the Processor ID 
    Function GetProcessorId() As String
        Dim query As New SelectQuery("Win32_processor")
        Dim search As New ManagementObjectSearcher(query)
        Dim info As ManagementObject
        For Each info In search.Get()
            Return info("processorId").ToString()
        Next
    End Function

' Generate Hash  
    Function GenerateHash(ByVal input As String) As String
        Dim hash = New SHA1Managed().ComputeHash(Encoding.UTF8.GetBytes(input))
        Return String.Concat(hash.[Select](Function(b) b.ToString("x2")))
    End Function


'Now display Hardware ID
MessageBox.Show(GenerateHash(GetMotherBoardID() & GetProcessorId()))

源代码：Code file、Binary executable。

处理器 ID 对所有计算机不是唯一的，但保持不变。 refernce
主板 ID 无法更改。 reference