在大型 Pandoc 中有效地搜索单个元素

Question

除非我遗漏了什么，否则似乎只有两种方法可以“遍历”Pandoc 数据结构：

1. 在 Block 和 Inline 构造函数上手动进行模式匹配
2. 通过Walkable type-class 和相关实用函数

使用Walkable 类型类，有没有一种有效的方法来搜索 first 匹配元素（最好以广度优先的方式），并在找到后立即停止遍历?在我看来，Walkable 类型类周围的所有函数无论如何都会遍历 整个 数据结构。

如果不是，我想唯一的方法是模式匹配 Block 和 Inline 构造函数并自己构建它。

Answer 1

另一个答案指出了有用的query 功能。我要补充一点，有一个package of pandoc lenses。你也问过广度优先遍历，所以这里都有。

import Data.Semigroup (First (..))

dfsFirstLink :: Walkable Inline b => b -> Maybe Text
dfsFirstLink = fmap getFirst . query (preview $ _Link . _2 . _1 . to First) 

bfsFirstLink :: Walkable Inline b => b -> Maybe Text
bfsFirstLink = fmap getFirst . getConst . traverseOf (levels query . folded) (Const . preview (_Link . _2 . _1 . to First))

-- Construct a walkable value where dfs != bfs
p :: Pandoc
p = Pandoc mempty [Plain [Note [Plain [Link mempty [] ("a","b")]]],Plain [Link mempty [] ("c","d")]]

>> dfsFirstLink p
Just "a"
>> bfsFirstLink p
Just "c"

尽管不幸的是，一些临时实验表明它可能不像人们希望的那样懒惰。

Answer 2

Walkable 类型类包含一个名为 query 的函数，其类型签名如下：

query :: Monoid c => (a -> c) -> b -> c

在Data.Semigroup 中，有一个名为First 的类型，带有一个半群实例，其中的累加行为是返回“最左边的值”。

这可以与Maybe 上的Monoid 结合使用，将任何Semigroup 转换为Monoid 与mempty 或Nothing，以提供您想要的行为。

例如，将函数从 Inline -> Maybe String 调整为 Pandoc -> Maybe String，可以这样完成：

import Text.Pandoc
import Text.Pandoc.Walk (query)
import Data.Semigroup

findUrl :: Inline -> Maybe String
findUrl (Link _ _ target) = Just $ fst target
findUrl _ = Nothing

findFirstUrl :: Pandoc -> Maybe String
findFirstUrl = (fmap getFirst) . (query findUrl')
  where
    findUrl' :: Inline -> Maybe (First String)
    findUrl' = (fmap First) . findUrl

关于您担心这将遍历整个数据结构：Haskell 是惰性的；它不应该比它需要的更远。

正如 cmets 中所指出的，也可以通过将 query 特化为 List Monoid 来编写：

import Text.Pandoc
import Text.Pandoc.Walk (query)
import Data.Maybe (listToMaybe)

findUrl :: Inline -> [String]
findUrl (Link _ _ target) = [fst target]
findUrl _ = []

findFirstUrl :: Pandoc -> Maybe String
findFirstUrl = listToMaybe . (query findUrl)