秩运算符与轴符号

Question

几年前，我在大型机上偷看了 APL2，并记得当时向我展示了向矩阵添加向量的问题的解决方案。

给定a←4 4 ⍴ ⍳16 和⎕io←1

向行添加向量的旧方法类似于

a+(⍴a)⍴10 20 30 40

导致

11 22 33 44
15 26 37 48
19 30 41 52
23 34 45 56

将向量添加到矩阵的列是

a+(4 1⍴10 20 30 40)[;1 1 1 1]

或者，如果你愿意，

a+4/4 1⍴10 20 30 40

导致

11 12 13 14
25 26 27 28
39 40 41 42
53 54 55 56

幸运的是，我能够打电话给那天向我展示 APL2 的那个人（他已经退休但仍然接听电话）并询问第二个解决方案，他立刻想起了我在说什么。

新的 APL2 方法更加简洁、简洁和一致，这些示例将由 a+[2] 10 20 30 40 和 a+[1] 10 20 30 40 解决。凉爽的。它在 Dyalog 中有效。

快进十年或更长时间，我发现有一个新事物叫做排名运算符。第一个例子可以a(+⍤1) 10 20 30 40解决（我还在努力掌握括号的用法，我想一旦我明白了一点，我就真的再生了一些脑细胞）

尽管如此，没有直接的（至少对我而言）类似于第二个示例a+[1] 10 20 30 40 使用排名运算符。我不能说我完全理解它，但在我看来，秩运算符通过折叠它的维度来“重新转换”它的左参数，同时保持内容完整。太多年的 C++ 和 Java 影响了我的思考方式。

对于a+[1] 10 20 30 40 使用排名运算符有简单的解决方案吗？到目前为止，我发现的唯一想法是⍉(⍉a)(+⍤1) 10 20 30 40，它没有抓住重点，违背了整个目的。

为什么秩运算符比轴表示法更可取？哪个更好”？ （可以肯定的是，这是一个加载的术语）乍一看，轴符号对我这个鞋码智商的人来说很容易掌握。对于排名运算符，我不能说同样的话。

Answer 1

对于a+[1] 10 20 30 40，有没有使用秩运算符的简单解决方案？

是的：a(+⍤1 0)10 20 30 40Try it online!
对于二元应用程序，秩运算符实际上需要一个两个元素的右操作数（但接受一个扩展为两个元素的单例）。 a(f⍤A B)b 表示 a 的 rank-A 子数组应与 b 的 rank-B 子数组配对。因此，在您的情况下，a(+⍤1)10 20 30 40（实际上是指a(+⍤1 1)10 20 30 40）表示应将a（行）的rank-1数组添加到10 20 30 40的rank-1数组（整个向量）。这里，a(+⍤1 0)10 20 30 40 表示 a（行）的 rank-1 数组应该添加到 10 20 30 40（标量）的 rank-0 数组中。

为什么秩运算符比轴表示法更可取？

rank 运算符允许您完全控制从每个参数中获取的内容，而括号轴表示法只允许您扩展较低级别的参数。秩运算符是语言的一个组成部分，可以与任何函数一起使用，甚至是用户定义的函数，而括号轴表示法只能与二元标量函数、归约函数和一小部分混合函数一起使用。

哪个“更好”？

由于等级运算符遵循运算符的正常 APL 语法并且普遍适用，因此它减少了要记住的规则数量。此外，排名运算符还允许通过使用负数来指定相对排名。因此，⍤1 表示 应用于等级为 1 的子数组，⍤¯1 表示应用于比整个参数低一级的子数组。在我看来，这足以安全地认为秩运算符比括号轴“更好”。

我仍在努力掌握括号的用法

我个人不喜欢括号，所以我知道你从哪里来。幸运的是，您可以随意减少括号的数量。 a(+⍤1)10 20 30 40 中括号的唯一原因是将数组操作数1 与数组参数10 20 30 40 分开。任何其他分离它们的方法也是可以接受的，我通常使用标识函数⊢：a+⍤1⊢10 20 30 40Try it online!
但是，您也可以将 curry right operands 转换为二元运算符，生成一元运算符，读起来非常好：horizontally←⍤1 0 ⋄ vertically←⍤1 1 Try it online!

完整的rank operator documentation is available online

Answer 2

多年来，一种流行的观点是应避免使用方括号，即函数的索引和轴“运算符”。造成这种情况的一些原因是方括号语法异常并且与语言的其余部分不一致，方括号内参数的语义在函数组之间不同，它使解析复杂化等等。 Google "apl axis operator anomalous" 有很多例子。

索引

旧版索引是熟悉的 x[i] 形式，替代方法包括 ⊃ "pick" 和 ⌷ "squad" 函数。更高维度的索引数组使用x[i;j;k;...;n] 形式，其中; 分隔各个维度表达式。这个表达可以省略以表示“所有那个维度”。然后是索引赋值，可以选择性地插入新值。

轴操作员

首先只规定了轴规格减少+/[1]a，压缩b/[1]a，扩展b\[1]a，最后旋转1⌽[2]x 和反向⌽[2]x。稍后扫描+\a，连接x,[1] y 和层压x,[0.5] y 也是如此。 （浮点“轴”- 好悲哀）APL2 引入了更多与您的示例 a +[2] b 不同的案例，并包含在任意坐标 ⊂[2] 上。

秩运算符提供了一种统一的方式来处理坐标规范。

Answer 3

我认为，要向矩阵添加向量，您不应再使用秩运算符搜索更简单的解决方案。我想引入秩运算符是为了实现原始标量函数的行为，也适用于定义的函数。也就是说，如果你有一个定义的函数，比如说

∇Z←A ADD B
 Z←A + B
∇

然后

a ADD[1] 10 20 30 40

会失败并迫使您使用排名运算符。 rank 运算符需要括号，因为它的语法有些可疑：

a +⍤1 10 20 30 40    ⍝ ???
a(+⍤1)10 20 30 40    ⍝ maybe this?
a(+⍤1 10) 20 30 40   ⍝ or maybe this?
a(+⍤1 10 20) 30 40   ⍝ or even this?

IBM 足够聪明，可以标准化秩运算符，但没有实现它（至少在我的 PC 演示版 APL2 中）。