找到一系列棒状值之间的最小和最大对应值答案

【问题标题】：To find the minimum and maximum corresponding value in between a range of clubbed values找到一系列棒状值之间的最小和最大对应值
【发布时间】：2019-10-10 22:41:00
【问题描述】：

我在编写公式时遇到了一个小问题。我有这种格式的数据：

NAME  |  EXP     |     SALARY

A     |  0.3     |      40000

B     |  4.7     |     490000

C     |  2.6     |     220000

D     |  3.9     |      34000

E     |  1.3     |     150000

F     |  3.2     |     300000

G     |  0.8     |      90000

H     |  1.9     |     170000

I     |  2.1     |     260000

J     |  4.1     |     390000

这就是我想要的输出：

EXP-RANGE  | MIN SALARY  |  MAX SALARY

0-1

1-2

2-3

3-4

4-5

我想找出经验范围内人员的最低和最高工资我尝试使用 MIN(IF()) 但它返回#VALUE？

我也可以将所有这些数据推送到数据库中并进行查询，但我非常感谢任何可以制定它的人，以便我可以在 Excel 本身上工作。数据大小为 20000+，所以我不喜欢过滤器

提前致谢

【问题讨论】：

所以如果有人有 1 年的经验，他们是否在两个范围内都计算在内？如果只有一个范围，1、2、3、4属于哪个范围？
我会更喜欢范围上限。1 属于 1-2，2 属于 2-3，依此类推。感谢编辑编辑。

标签： excel-formula

【解决方案1】：

使用 MAXIFS 和 MINIFS：

=MINIFS(C:C,B:B,">="&LEFT(G2,FIND("-",G2)-1),B:B,"<"&MID(G2,FIND("-",G2)+1,LEN(G2)))
=MAXIFS(C:C,B:B,">="&LEFT(G2,FIND("-",G2)-1),B:B,"<"&MID(G2,FIND("-",G2)+1,LEN(G2)))

如果没有 MAXIFS 或 MINIFS，我们可以使用 AGGREGATE：

=AGGREGATE(15,7,$C$2:$C$11/(($B$2:$B$11>=--LEFT(G2,FIND("-",G2)-1))*($B$2:$B$11<--MID(G2,FIND("-",G2)+1,LEN(G2)))),1)
=AGGREGATE(14,7,$C$2:$C$11/(($B$2:$B$11>=--LEFT(G2,FIND("-",G2)-1))*($B$2:$B$11<--MID(G2,FIND("-",G2)+1,LEN(G2)))),1)

AGGREGATE 是数组类型公式，引用应限于数据集。

【讨论】：

感谢@ScottCraner。我似乎没有 MINIFS 或 MAXIFS，感谢您提供 Aggregate 选项！
你能解释一下这部分吗：MID(G2,FIND("-",G2)+1,LEN(G2)
@SandeepNair MID(G2,FIND("-",G2)+1,LEN(G2) 如果在你的 EXP RANGE 中从 x-y 找到 y。

【解决方案2】：

假设“查找表”放入A1:C11

G1:G6 中带有标头的条件

在H2（最低工资）中，将公式复制到I2（最高工资）并全部复制下来：

=AGGREGATE(14+(COLUMN(A1)=1),6,$C$2:$C$11/($B$2:$B$11>=IMREAL($G2&"i"))/($B$2:$B$11<-IMAGINARY($G2&"i")),1)

编辑：在将条件“0-1”转换为复数“0-1i”时，IMREAL() 提取左侧数字“0”，而 IMAGINARY() 提取右侧数字“@ 987654329@"

=AGGREGATE(14+(COLUMN(A1)=1),6,..., 在 K 列返回 =AGGREGATE(15,6,....) 和 L 列 =AGGREGATE(14,6,...)

【讨论】：