Excel2011 - 按日期查找并将多个值返回到一个单元格中答案

【问题标题】：Excel2011 - Lookup and return multiple values into one cell BY DATEExcel2011 - 按日期查找并将多个值返回到一个单元格中
【发布时间】：2017-06-24 03:25:21
【问题描述】：

我需要查找数字（循环）并返回数字旁边的单元格的值，但仅限于同一日期。结果必须连接到同一个目标单元格中。

我在 Mac 上使用 Excel 2011。我没有 Textjoin 功能。但是，我找到了一个 VBA UDF 来查找多个值并将其返回到一个单元格中。这是我正在使用的：

Function MYVLOOKUP(pValue As String, pWorkRng As Range, pIndex As Long)
'Update 20150310
Dim rng As Range
Dim xResult As String
xResult = ""
For Each rng In pWorkRng
    If rng = pValue Then
        xResult = xResult & " " & rng.Offset(0, pIndex - 1)
    End If
Next
MYVLOOKUP = xResult
End Function

它有点工作，但仅用于在一个单元格中查找值并在另一列中找到它。问题是我正在查找的值在不同的日期重复，我只想返回给定日期的值。我在下面附上了我正在尝试做的示例：

Sample Spreadsheet

注意“所需数据格式”G2 正在返回数据库中两个日期的员工 1001 的数据，但我只希望它返回相关日期的数据，所以我尝试在 myvlookup UDF 中设置第一个变量到“E2：F2”，以便该函数同时查找日期和员工编号，但该函数似乎无法以这种方式工作。

G2中应显示的值为“80011、80025”，G3中应显示的值为“80011、80030”等。

我希望我有更多时间自己解决这个问题，但时间很重要，所以我需要帮助。

【问题讨论】：

标签： excel vba

【解决方案1】：

这是一个模仿 TEXTJOIN() 的 UDF：

Function TEXTJOIN(delim As String, skipblank As Boolean, arr)
    Dim d As Long
    Dim c As Long
    Dim arr2()
    Dim t As Long, y As Long
    t = -1
    y = -1
    If TypeName(arr) = "Range" Then
        arr2 = arr.Value
    Else
        arr2 = arr
    End If
    On Error Resume Next
    t = UBound(arr2, 2)
    y = UBound(arr2, 1)
    On Error GoTo 0

    If t >= 0 And y >= 0 Then
        For c = LBound(arr2, 1) To UBound(arr2, 1)
            For d = LBound(arr2, 1) To UBound(arr2, 2)
                If arr2(c, d) <> "" Or Not skipblank Then
                    TEXTJOIN = TEXTJOIN & arr2(c, d) & delim
                End If
            Next d
        Next c
    Else
        For c = LBound(arr2) To UBound(arr2)
            If arr2(c) <> "" Or Not skipblank Then
                TEXTJOIN = TEXTJOIN & arr2(c) & delim
            End If
        Next c
    End If
    TEXTJOIN = Left(TEXTJOIN, Len(TEXTJOIN) - Len(delim))
End Function

您可以在数组公式中使用您的数据：

=TEXTJOIN(" ",TRUE,IF((F2=B$2:B$14)*(A$2:A$14=E2),C$2:C$14,""))

作为数组公式，退出编辑模式时需要使用 Ctrl-Shift-Enter 确认，而不是 Enter。如果操作正确，Excel 会在公式周围加上{}。

【讨论】：