Perl 使用 File::Find 重命名文件夹和文件

Question

我正在使用此代码来处理我的文件夹和文件，其中包含两个子：
“子文件夹”仅用于文件夹名称
仅带有扩展名的文件名的“子文件”

但我意识到“子文件夹”在重命名过程中会与我的带有扩展名的文件混淆。

如何区分进程，或者告诉“子文件夹”重命名不带扩展名的“名称”和“子文件”重命名带有扩展名的“名称”的智能方法是什么？

find(\&folders, $dir_source); 
sub folders {
    my $fh = $File::Find::dir;
    my $artist = (File::Spec->splitdir($fh))[3];        

    if (-d $fh) {
        my $folder_name = $_;

        # some substitution

        rename $folder_name, $_;
    }
}


find(\&files, $dir_source); 
sub files {
    /\.\w+$/ or return;
    my $fn = $File::Find::name;

    my ($genre, $artist, $boxset, $album, $disc);   
    if ($fn =~ /Singles/ or $fn =~ /Box Set/) {
         ($genre, $artist, $boxset, $album, $disc) = (File::Spec->splitdir($fn))[2..6];
     }
     else {
         ($genre, $artist, $album, $disc) = (File::Spec->splitdir($fn))[2..5];
     }

     if (-e $fn) {
         my $file_name = $_;

         # some substitution

         rename $file_name, $_;
     }  
 }

Answer 1

File::Find::find() 为每个文件和文件夹调用您的子程序。如果您只想影响文件夹，则忽略文件：

而且您需要调用 finddepth() 而不是 find()，因为您正在更改目录名称（您需要在更“浅”的目录之前重命名“更深”的目录）。

finddepth(sub {
  return unless -d;

  (my $new = $_) =~ s/this/that/ or return;
  rename $_, $new or warn "Err renaming $_ to $new in $File::Find::dir: $!";
}, ".");

多个替换的替代方案：

finddepth(sub {
  return unless -d;

  my $new = $_;
  for ($new) {
    s/this/that/;
    s/something/something_else/;
  }
  return if $_ eq $new;

  rename $_, $new or warn "Err renaming $_ to $new in $File::Find::dir: $!";
}, ".");

在文件 sub 中，我会做第一个声明：

return unless -f;