如何在cmd中获取小写的当前文件夹名称作为变量？

Question

我正在尝试以小写形式获取当前目录文件夹名称。

我知道我可以通过以下方式获取当前文件夹名称：

for %I in (.) do echo %~nxI

但我不知道如何将其转换为小写。

我需要在单行命令中使用它。

for %I in (.) do echo %~nxI

我追求的是什么：

c:\Program Files
for %I in (.) do echo %~nxI ---edited
program files

目前正在获取

c:\Program Files
for %I in (.) do echo %~nxI
Program Files

Answer 1

这是一种使用dir /b /l 的方法，但与Gerhard's answer 不同的是，它不需要临时文件。

从命令行：

for %A in (.) do @for /f "eol=: delims=" %F in ('dir /b /l /ad "..\%~nxA*"^|findstr /xic:"%~nxA"') do @echo %F

在批处理脚本中：

@echo off
for %%A in (.) do for /f "eol=: delims=" %%F in (
  'dir /b /l /ad "..\%%~nxA*" ^| findstr /xic:"%%~nxA"'
) do echo %%F

Answer 2

使用纯批处理，带有临时文件：

单行cmd:

@for %i in (.) do echo>"%temp%\%~nxi" & @dir /b /l "%temp%\%~nxi" & @del /Q "%temp%\%~nxi"

或batch-file

@echo off
for %%i in (.) do set "var=%%~nxi"
echo>"%temp%\%var%"
for /f "delims=" %%a in ('dir /b /l "%temp%\%var%"') do echo %%a & del /Q "%temp%\%var%"

或略短，没有回声：

@echo off
for %%i in (.) do (
  echo>"%temp%\%%~nxi"
  dir /b /l "%temp%\%%~nxi"
  del /Q "%temp%\%%~nxi"
)

Answer 3

如果您在受支持的 Windows 平台上，它将具有 PowerShell。

powershell -NoLogo -NoProfile -Command "(Split-Path -Leaf -Path (Get-Location)).ToLower()"

如果您希望将结果放在 .bat 文件脚本中的变量中：

FOR /F "delims=" %%A IN ('powershell -NoLogo -NoProfile -Command "(Split-Path -Leaf -Path (Get-Location)).ToLower()"') DO (SET "LCCD=%%~A")
ECHO %LCCD%

当然，如果你可以在没有 cmd.exe 的情况下使用 PowerShell，那就是：

(Split-Path -Leaf -Path (Get-Location)).ToLower()