Scheme中的尾递归帕斯卡三角形

Question

我最近开始阅读SICP，我对将递归过程转换为尾递归形式非常感兴趣。

对于“一维”情况（线性情况），例如斐波那契数列或阶乘计算，进行转换并不难。

例如，正如书中所说，我们可以将斐波那契计算重写如下

(define (fib n)
    (fib-iter 1 0 n))
(define (fib-iter a b count)
    (if (= count 0) 
        b 
        (fib-iter (+ a b) a (- count 1))))

而且这种形式显然是尾递归

但是，对于“二维”情况，例如计算帕斯卡三角形（SICP 中的 Ex 1.12），我们仍然可以轻松编写如下递归解决方案

(define (pascal x y) 
  (cond ((or (<= x 0) (<= y 0) (< x y )) 0)
        ((or (= 1 y) (= x y) ) 1)
        (else (+ (pascal (- x 1) y) (pascal (- x 1) (- y 1))))))

问题是，如何将其转化为尾递归形式？

Answer 1

首先，递归过程pascal 过程可以用更简单的方式表示（假设非负的有效输入）——像这样：

(define (pascal x y) 
  (if (or (zero? y) (= x y))
      1
      (+ (pascal (sub1 x) y)
         (pascal (sub1 x) (sub1 y)))))

现在回答问题。 可以将递归过程实现转换为使用尾递归的迭代过程版本。但它比看起来更棘手，要完全理解它，您必须掌握动态编程的工作原理。有关此算法的详细说明，请参阅 Steven Skiena 的The Algorithm Design Manual，第 2 版，第 278 页。

这种算法不适用于 Scheme 中的惯用解决方案，因为它要求我们改变状态作为解决方案的一部分（在这种情况下，我们正在更新向量中的部分结果） .这是一个相当人为的解决方案，我优化了表内存使用，因此一次只需要一行 - 就是这样：

(define (pascal x y)
  (let ([table (make-vector (add1 x) 1)])
    (let outer ([i 1])
      (when (<= i x)
        (let inner ([j 1] [previous 1])
          (when (< j i)
            (let ([current (vector-ref table j)])
              (vector-set! table j (+ current previous))
              (inner (add1 j) current))))
        (outer (add1 i))))
    (vector-ref table y)))

事实上，在这种情况下，编写一个直接迭代并沿途改变变量会更自然。在Racket 中是这样的：

(define (pascal x y)
  (define current null)
  (define previous null)
  (define table (make-vector (add1 x) 1))
  (for ([i (in-range 1 (add1 x))])
    (set! previous 1)
    (for ([j (in-range 1 i)])
      (set! current (vector-ref table j))
      (vector-set! table j (+ (vector-ref table j) previous))
      (set! previous current)))
  (vector-ref table y))

我们可以打印结果并检查显示的所有三个实现是否都有效。同样，在Racket：

(define (pascal-triangle n)
  (for ([x (in-range 0 n)])
    (for ([y (in-range 0 (add1 x))])
      (printf "~a " (pascal x y)))
    (newline)))

(pascal-triangle 5)

1 
1 1 
1 2 1 
1 3 3 1 
1 4 6 4 1 

Answer 2

更新：这个问题有一个far easier math solution，你可以只使用阶乘得到 O(row)。基于此，这归结为：

(define (pascal-on row col)
  (define (factorial from to acc)
    (if (> from to)
        acc
        (factorial (+ 1 from) to (* acc from))))

  (let* ((rmc (- row col))
         (fac-rmc (factorial 1 rmc 1))
         (fac-pos (factorial (+ rmc 1) col fac-rmc))
         (fac-row (factorial (+ col 1) row fac-pos)))
    (/ fac-row fac-pos fac-rmc)))

旧答案：

您需要研究这些模式。基本上，您希望从三角形的开头进行迭代，直到您有足够的信息来产生结果。很明显，您需要前一行来计算下一行，因此它必须是您给它的参数，并且如果请求的行不是当前行，它必须提供下一行。此解决方案具有尾递归性和闪电般的速度。

(define (pascal row col)
  (define (aux tr tc prev acc)
    (cond ((> tr row) #f)              ; invalid input

          ((and (= col tc) (= row tr)) ; the next number is the answer
           (+ (car prev) (cadr prev))) 

          ((= tc tr)                   ; new row 
           (aux (+ tr 1) 1 (cons 1 acc) '(1)))

          (else (aux tr               ; new column
                     (+ tc 1) 
                     (cdr prev)
                     (cons (+ (car prev) (cadr prev)) acc))))) 

  (if (or (zero? col) (= col row))
      1
      (aux 2 1 '(1 1) '(1))))

Answer 3

要添加到Óscar's answer，我们可以使用continuation-passing style 将任何程序转换为使用尾调用：

;; Int Int (Int → Int) → Int
(define (pascal/k x y k)
  (cond
   [(or (<= x 0) (<= y 0) (< x y)) (k 0)]
   [(or (= 1 y) (= x y)) (k 1)]
   [else (pascal/k (- x 1) y
                   (λ (a)
                     (pascal/k (- x 1) (- y 1)
                               (λ (b) (k (+ a b))))))]))

;; Int Int → Int
(define (pascal x y) (pascal/k x y (λ (x) x)))

你可能会说这个程序并不令人满意，因为有一个“增长”的闭包。但是它们是在堆上分配的。在一般情况下，尾部调用的重点与其说是性能，不如说是空间安全：您不会破坏评估上下文。