Haskell 错误 - 无法将预期类型“Char”与实际类型“[Char]”匹配

Question

我正在尝试编写一个 Haskell 函数，该函数将获取一个人的全名并仅返回姓氏；例如，getName "Hans Christian Anderson" 应该返回 "Anderson"。函数如下：

getname :: String -> String
getname fullName = do
  let nameList = splitOn " " fullName    -- split the full name into individual names
  let reversedName = reverse nameList    -- reverse the full name
  let lastName = reversedName !! 0       -- get the first name from the reversed list
  return lastName

但是每当我尝试编译它时，我都会收到以下错误：

Couldn't match expected type ‘Char’ with actual type ‘[Char]’
In the first argument of ‘return’, namely ‘lastName’
In a stmt of a 'do' block: return lastName

我不确定我是否完全理解此错误。据我了解 Haskell（我对它很陌生）结构 [Char] 将与 String 相同，这就是我正在寻找的。我只是不明白为什么它期待这个Char 类型，它似乎作为字符串出现在return 语句中。我已经检查了每一行，它们对我来说似乎是正确的。

非常感谢任何关于为什么会发生这种行为以及如何解决它的建议。

Answer 1

这里不要使用do 表示法。因为您的函数的返回值是[Char]，所以return 的参数应该是Char 值（因为return :: a -> [a]）。

您在这里没有做任何需要do 表示法的事情；只需使用常规函数调用。

getname fullName = (reverse (splitOn " " fullName)) !! 0

Answer 2

您的代码意外地在 list monad 中运行，就好像它是用来描述非确定性计算一样。你不需要那个单子，也不需要任何其他单子。因此，请避免为此使用do。如果你愿意，你仍然可以使用let .. in ..：

getname :: String -> String
getname fullName =
  let nameList = splitOn " " fullName    -- split the full name into individual names
      reversedName = reverse nameList    -- reverse the full name
      lastName = reversedName !! 0       -- get the first name from the reversed list
  in lastName

或者，使用last:

getname :: String -> String
getname fullName = last (splitOn " " fullName)

注意last 是不完整的：只要输入字符串中没有名称，它就会使您的程序崩溃。更安全的方法可能是：

getname :: String -> Maybe String
getname fullName = case splitOn " " fullName of
   [] -> Nothing
   xs -> Just (last xs)

甚至：

getname :: String -> Maybe String
getname fullName = safeLast (splitOn " " fullName)

-- This should be already there in the library, IMO
safeLast :: [a] -> Maybe a
safeLast []     = Nothing
safeLast [x]    = Just x
safeLast (_:xs) = safeLast xs