记录在案的通用方法

Question

我想知道是否有更好的方法来实现接受记录并修改它们的函数。

所以我有两种类型的实体，在磁盘上都有对应的文件：

type Picture = { Artist : string; File : string }
type Book = { Author : string; File : string }

我想要可以复制图片和书籍的通用功能。在 OOP 世界中，我可能会创建公共接口 IArtefact { File : string }，在两条记录中实现它，然后创建适用于它的 Move 方法。比如：

let move<'a:IArtefact>(a : 'a) (path : string) =
    File.Move(a.File, path)
    { a with File = path }

但是我认为 F# 不支持这样的概念。这样做的 F# 方式是什么？

Answer 1

这是可能的，为什么不呢;)

type IArtefact = 
    abstract File: string

type Picture = 
    { Artist : string; File : string }
    interface IArtefact with
        member this.File = this.File

let p = { Artist = "test"; File = "test2" }
(p :> IArtefact).File

编辑：如果你想处理更新：

type IArtefact = 
    abstract File: string
    abstract WithFile: string -> IArtefact

type Picture = 
    { Artist : string; File : string }
    interface IArtefact with
        member this.File = this.File
        member this.WithFile(file) = { this with File = file } :> IArtefact

Answer 2

虽然没有通用的更改复制记录的方法，但有一种方法可以移动具有File 的任何内容：

let inline move from where : string =
    let oldFile = (^T : (member File : string) from)
    do() // move here
    where

type Picture = { Artist: string; File: string }
type Book = { Author: string; File: string }

let p = { Artist = "Vincent van Gogh"; File = "Rooftops" }
let p' = { p with File = move p "The Potato Eaters" }

let b = { Author = "Don Syme"; File = "Generics in CLR" }
let b' = { b with File = move b "Expert F#" }

然后可以扩展它以移动任何知道如何移动的东西：

let inline move' a where =
    let oldFile = (^T : (member File : string) a)
    do() // move here
    (^T: (member moved : string -> ^T) a, where)

type Picture' =
    { Artist: string; File: string } with
    member this.moved where = { this with File = where }

type Book' =
    { Author: string; File: string } with
    member this.moved where = { this with File = where }

let p2 = { Artist = "Vincent van Gogh"; File = "Rooftops" }
let p2' = move' p2 "The Potato Eaters"

let b2 = { Author = "Don Syme"; File = "Generics in CLR" }
let b2' = move' b2 "Expert F#"