将 JSON 反序列化为类型对象数组 (Delphi 11)答案

【问题标题】：Deserialize JSON into array of typed objects (Delphi 11)将 JSON 反序列化为类型对象数组 (Delphi 11)
【发布时间】：2021-10-13 03:58:25
【问题描述】：

我正在尝试反序列化来自 Web 服务的 JSON 响应。响应采用类型良好的对象数组的形式。例如，我使用的是 songster.com。

在以下（摘录）代码中，显然TSongsterResponse 不正确，因为我要收回一个集合。但是array of TSongsterResponse 和TSongsterList 都不会编译。

interface

type
  TSongsterResponse = class
    public
      id: integer;
      title: string;
  end;

type TSongsterList = array of TSongsterResponse;

implementation

procedure Sample(AJson: string);
begin
  // What goes here to get an array of TSongsterResponse?
  FSomething :=   TJson.JsonToObject<?????>(RESTResponse1.Content);
end;

【问题讨论】：

@RemyLebeau 我试着按照那个例子，但我希望从每个数组值中获取一个类型化的对象，而那个例子是从一个通用的 TJsonObject 中提取一个字符串值。我看不到如何修改内部循环来为每个数组项生成一个 TSongsterResponse。
查看我刚刚发布的答案

标签： json delphi

【解决方案1】：

TJson.JsonToObject()，顾名思义，需要对象类型，而不是数组类型。它具有class, constructor 的通用约束，这意味着它必须能够Create 一个要反序列化的对象。它无法反序列化不在 JSON 对象内的 JSON 数组。

您可以尝试用'{...}' 包装RESTResponse1.Content，否则您可能只需要改用TJSONObject.ParseJSONValue() 并自己手动构建TSongsterList（请参阅Delphi parse JSON array or array）。

查看正在解析的实际 JSON 会有所帮助，但没有什么能阻止您定义自己的类类型以将 JSON 值复制到其中。例如：

interface

type
  TSongsterResponse = class
  public
    id: integer;
    title: string;
  end;

  TSongsterList = array of TSongsterResponse;

implementation

uses
  System.JSON;

var
  FSomething: TSongsterList;

procedure Sample(AJson: string);
var
  Value: TJSONValue;
  Arr: TJSONArray;
  Obj: TJSONObject;
  Song: TSongsterResponse;
  I: Integer;
begin
  Value := TJSONObject.ParseJSONValue(AJson);
  if Value = nil then Exit;
  try
    Arr := Value as TJSONArray;
    SetLength(FSomething, Arr.Count);
    for I := 0 to Arr.Count-1 do
    begin
      Obj := Arr[I] as TJSONObject;
      Song := TSongsterResponse.Create;
      try
        Song.id := (Obj.GetValue('id') as TJSONNumber).AsInt;
        Song.title := Obj.GetValue('title').Value;
        FSomething[I] := Song;
      except
        Song.Free;
        raise;
      end;
    end;
  finally
    Value.Free;
  end;
  // use FSomething as needed...
end;
...
Sample(RESTResponse1.Content);

话虽如此，请注意TRESTResponse 有一个JSONValue 属性可以为您解析接收到的JSON 内容，例如：

interface

type
  TSongsterResponse = class
  public
    id: integer;
    title: string;
  end;

  TSongsterList = array of TSongsterResponse;

implementation

uses
  System.JSON;

var
  FSomething: TSongsterList;

procedure Sample(AJson: TJSONValue);
var
  Arr: TJSONArray;
  ...
begin
  Arr := AJson as TJSONArray;
  // process Arr same as above...
  // use FSomething as needed...
end;
...
Sample(RESTResponse1.JSONValue);

【讨论】：