为自定义树创建自定义折叠函数

Question

我正在尝试创建我自己的折叠函数，然后我可以在我的自定义树上使用它。

我的树很简单：

data Stem a = Node (Stem a) (Stem a) | Leaf a

我希望能够构建一个foldTree 函数，它的工作方式与foldr 的工作方式大致相同。

我已经设法让它在 n=1 或只是 leaf 的时候工作

foldTree :: (x -> u -> u) -> u -> Stem x -> u
foldTree f a (Leaf o) = f o a

但我似乎无法计算出下一行（IE 表示当有节点和叶子时），我知道我需要递归调用 foldTree 但我不确定我该怎么做。我尝试了以下方法，但运气不佳。

foldTree f a (Node l r) = f a (foldTree f a l) (foldTree f a r)

这不起作用，因为我知道我的参数是x -> u -> u，所以我的参数太多了。虽然这是我卡住的地方，但我不确定如何正确遍历这两条路径。

所以我在一起

foldTree :: (x -> u -> u) -> u -> Stem x -> u
foldTree f a (Leaf o) = f o a
foldTree f a (Node l r) = f a (foldTree f a l) (foldTree f a r) <-- Not working

如何更新第二行（或方法中的其他内容以使其正常工作？

感谢您的帮助！

Answer 1

首先处理简单的具体案例，然后将逻辑扩展到一般案例。 Leaf：

foldTree f a (Leaf o) = f o a

然后想想你想在只有两个Leafs 的Node 的情况下发生什么：

foldTree f a (Node (Leaf x) (Leaf y)) = _

这里我们知道f 必须被应用两次，但顺序是什么？让我们从Node 的第一个槽中的Leaf 开始：

foldTree f a (Node (Leaf x) (Leaf y)) = _ (f x a)

我在表达式中留下了漏洞 (_)，因为当您尝试编译时，GHC 实际上会告诉您需要什么类型的东西去那里。在这种情况下，它会说你需要u -> u 类型的东西，因为f x a :: u。好吧，我们知道f :: x -> u -> u，所以我们可以写

foldTree f a (Node (Leaf x) (Leaf y)) = f _ (f x a)

现在唯一能填补这个洞的就是来自右叶的y，所以

foldTree f a (Node (Leaf x) (Leaf y)) = f y (f x a)

但我们知道f x a 与foldTree f a (Leaf x) 相同，因此我们可以将其替换为：

foldTree f a (Node (Leaf x) (Leaf y)) = f y (foldTree f a (Leaf x))

然后用一个变量替换Leaf x：

foldTree f a (Node left (Leaf y)) = f y (foldTree f a left)

如果您眯起眼睛仔细观察，您会再次看到相同的图案。只需快速替换

foldTree f a (Node left (Leaf y)) = f y a'
  where a' = foldTree f a left

现在你可以进行替换

foldTree f a (Node left right) = foldTree f a' right
  where a' = foldTree f a left

整个定义是

foldTree f a (Leaf x) = f x a
foldTree f a (Node left right) = foldTree f (foldTree f a left) right