有没有办法将word文档升级到2010

Question

场景：我有大约 14000 个 word 文档需要从“Microsoft Word 97 - 2003 Document”转换为“Microsoft Word Document”。换句话说，升级到 2010 格式 (.docx)。

问题：有没有使用 API 或其他东西的简单方法？

注意：我只能找到一个将文档转换为 .docx 的 Microsoft 程序，但它们仍以兼容模式打开。如果可以将它们转换为新格式，那就太好了。与打开旧文档时获得的功能相同，它为您提供了转换它的选项。

编辑：刚刚找到http://msdn.microsoft.com/en-us/library/microsoft.office.interop.word._document.convert.aspx，正在研究如何使用它。

EDIT2：这是我当前用于转换文档的功能

Private Sub btnConvert_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnConvert.Click
    FolderBrowserDialog1.ShowDialog()
    Dim mainThread As Thread
    If Not String.IsNullOrEmpty(FolderBrowserDialog1.SelectedPath) Then
        lstFiles.Clear()

        DirSearch(FolderBrowserDialog1.SelectedPath)
        ThreadPool.SetMaxThreads(1, 1)
        lstFiles.RemoveAll(Function(y) y.Contains(".docx"))
        TextBox1.Text += "Conversion started at " & DateTime.Now().ToString & Environment.NewLine
        For Each x In lstFiles
            ThreadPool.QueueUserWorkItem(New WaitCallback(AddressOf ConvertDoc), x)
        Next

    End If
End Sub
Private Sub ConvertDoc(ByVal path As String)
    Dim word As New Microsoft.Office.Interop.Word.Application
    Dim doc As Microsoft.Office.Interop.Word.Document
    word.Visible = False

    Try
        Debug.Print(path)
        doc = word.Documents.Open(path, Type.Missing, Type.Missing, Type.Missing, Type.Missing, Type.Missing, Type.Missing, Type.Missing, Type.Missing, Type.Missing, Type.Missing, Type.Missing, Type.Missing, Type.Missing, Type.Missing, Type.Missing)
        doc.Convert()

    Catch ex As Exception
        ''do nothing
    Finally
        doc.Close()
        word.Quit()
    End Try

End Sub`

它让我选择一个路径，然后在子文件夹中查找所有 doc 文件。该代码并不重要，所有要转换的文件都在 lstFiles 中。目前唯一的问题是即使只转换 10 个文档也需要很长时间。我应该为每个文档使用一个 word 应用程序而不是重复使用它吗？有什么建议吗？

它还会在大约 2 或 3 次转换后打开 word 并开始闪烁但一直在转换。

EDIT3：对上面的代码稍作调整，运行起来更干净。转换 8 个文件需要 1 分钟 10 秒。考虑到我有 14000，我需要转换此方法需要相当长的时间。

EDIT4：再次更改代码。现在使用线程池。好像跑的快了一些。仍然需要在更好的计算机上运行才能转换所有文档。或者按文件夹慢慢做。谁能想到任何其他方式来优化它？

Answer 1

我在本地运行了您的代码，只进行了一些小的编辑以改进跟踪和计时，并且它“仅”花费了 13.73 秒来处理 12 个文件。这将在大约 4 小时内照顾您的 14,000 个。我在带有双核处理器的 Windows 7 x64 上运行 Visual Studio 2010。也许您可以使用速度更快的计算机？

这是我的完整代码，这只是一个带有单个按钮 Button1 和一个 FolderBrowserDialog FolderBrowserDialog1 的表单：

Imports System.IO

Public Class Form1

Dim lstFiles As List(Of String) = New List(Of String)

Private Sub DirSearch(path As String)


    Dim thingies = From file In Directory.GetFiles(path) Where file.EndsWith(".doc") Select file

    lstFiles.AddRange(thingies)

    For Each subdir As String In Directory.GetDirectories(path)
        DirSearch(subdir)
    Next
End Sub

Private Sub Button1_Click(sender As System.Object, e As System.EventArgs) Handles Button1.Click
    FolderBrowserDialog1.ShowDialog()

    If Not String.IsNullOrEmpty(FolderBrowserDialog1.SelectedPath) Then
        lstFiles.Clear()

        DirSearch(FolderBrowserDialog1.SelectedPath)
        Dim word As New Microsoft.Office.Interop.Word.Application
        Dim doc As Microsoft.Office.Interop.Word.Document
        lstFiles.RemoveAll(Function(y) y.Contains(".docx"))
        Dim startTime As DateTime = DateTime.Now
        Debug.Print("Timer started at " & DateTime.Now().ToString & Environment.NewLine)
        For Each x In lstFiles
            word.Visible = False
            Debug.Print(x + Environment.NewLine)
            doc = word.Documents.Open(x)
            doc.Convert()
            doc.Close()
        Next
        word.Quit()
        Dim endTime As DateTime = DateTime.Now
        Debug.Print("Took " & endTime.Subtract(startTime).TotalSeconds & " to process " & lstFiles.Count & " documents" & Environment.NewLine)
    End If

End Sub
End Class

Answer 2

使用 word 自动化并打开它并使用 wdFormatDocumentDefault 的 WdSaveFormat 枚举保存它，它应该是 docx

http://msdn.microsoft.com/en-us/library/microsoft.office.interop.word.wdsaveformat%28v=office.14%29.aspx

或者试试你提到的转换方法。无论哪种方式都是 100% 可能的，而且应该相当容易。

编辑：如果转换器 Daniel 发布了作品，那就容易多了，他值得所有的功劳：)

Answer 3

您可以使用免费的 Office 文件转换器。

这里解释设置：

http://technet.microsoft.com/en-us/library/cc179019.aspx

有一个文件列表设置。

Answer 4

试试这个：

using Microsoft.Office.Interop
Microsoft.Office.Interop.Word.ApplicationClass word = new ApplicationClass();
object nullvalue = Type.Missing;
object filee = filename;
object file2 = String.Format("{0}{1}", filepath, "convertedfile.doc");
Microsoft.Office.Interop.Word.Document doc = word.Documents.Open(ref filee, ref nullvalue, ref nullvalue, ref nullvalue, ref nullvalue, ref nullvalue, ref nullvalue, ref nullvalue, ref nullvalue, ref nullvalue, ref nullvalue, ref nullvalue, ref nullvalue, ref nullvalue, ref nullvalue, ref nullvalue);
        doc.SaveAs(ref file2, ref nullvalue, ref nullvalue, ref nullvalue, ref nullvalue, ref nullvalue, ref nullvalue, ref nullvalue, ref nullvalue, ref nullvalue, ref nullvalue, ref nullvalue, ref nullvalue, ref nullvalue, ref nullvalue, ref nullvalue);