Outlook 电子邮件中的文本框

Question

下面是两组删除文本框的 VBA 代码，第一组在 MS Excel 中工作，第二组在 MS Word 中工作。两者之间的唯一区别是“Active”之后的第三行。

我正在尝试在新打开的电子邮件中复制 MS Outlook 中的此操作，但缺乏正确的代码术语知识...有没有人知道这个问题的答案？...谢谢， .

Sub RemoveTextBox()
    Dim shp As Shape
    For Each shp In ActiveSheet.Shapes
        If shp.Type = msoTextBox Then shp.Delete
    Next shp
End Sub

---

Sub RemoveTextBox()
    Dim shp As Shape
    For Each shp In ActiveDocument.Shapes
        If shp.Type = msoTextBox Then shp.Delete
    Next shp
End Sub

Answer 1

对于 Outlook，它将类似于以下示例

Option Explicit
Public Sub Example()
    Dim Inspector As Outlook.Inspector
    Dim wdDoc As Word.Document
    Dim Shp As Word.Shape

    Set Inspector = Application.ActiveInspector()
    Set wdDoc = Inspector.WordEditor

    For Each Shp In wdDoc.Shapes

        Debug.Print Shp.Type 'msoTextBox = 17 - Print on Immediate Window
        If Shp.Type = msoTextBox Then Shp.Delete

    Next

End Sub

对于开放式电子邮件，请使用 Application.ActiveInspector Method (Outlook) 和 Inspector.WordEditor Property (Outlook)

_{Inspector.WordEditor Property (Outlook) 返回正在显示的消息的 Microsoft Word 文档对象模型。只读，仅当 IsWordMail 方法返回 True 且 EditorType 属性为 olEditorWord 时，WordEditor 属性才有效。返回的 WordDocument 对象提供对大多数 Word 对象模型的访问，但以下成员除外：}

---

_{Application.ActiveInspector Method (Outlook) 返回桌面上最顶端的 Inspector 对象。}

---

Remember to add reference to word xx object library

---

_{1.从“工具”菜单中，选择“参考”以显示“参考”对话框。}

_{2. References 对话框显示向操作系统注册的所有对象库。滚动浏览要引用其对象库的应用程序的列表。如果应用程序未列出，您可以使用浏览按钮搜索对象库（}.olb 和 .tlb）或可执行文件（.exe 和 .dll 在 Windows 上）。您的项目使用复选框被选中的引用；没有勾选的不使用，但可以添加。