从 EVA 格式解析数据答案

【问题标题】：Parsing data from EVA format从 EVA 格式解析数据
【发布时间】：2014-11-30 07:55:29
【问题描述】：

我正在尝试从EVA 二进制数据库中获取数据，其中字段由一些特殊符号分隔。到目前为止，我已经设法将日期转换为以下格式的类似 XML 的文本文件。请注意字段的顺序如何变化，并且并非所有字段都是强制性的。

<251>id1<230><223>author1<228><215>title1<223><230>year1<225><232>location1<226>
<251>id2<230><223>author2<228><230>year2<225><232>location2<226><215>title2<223>
<251>id3<230><230>year2<225><232>location2<226><215>title2<223>

每一行都是单独的条目，对于每一行我都想得到类似的东西

251=id1
223=author1

等等

现在我正在努力从中解析数据。我通常使用explode函数并定义分隔符，但在这里我不能这样做，因为那样我会丢失某个子字符串属于哪个字段的信息。

也许我应该提一下，最后我想生成一个 CSV 文件，所以也许有一种方法可以直接从我的文本文件中解析它，从而跳过分别解析每个数据的冗余过程，然后以另一种格式再次合并它.

【问题讨论】：

第二个数字是多少？
第二个数字是多余的；它只是告诉该块已关闭

标签： java regex awk

【解决方案1】：

像这样？

$ cat tst.awk
BEGIN {
    FS="[<>]+"
    OFS="="
}
{
    for (i=2;i<NF;i+=3) {
        print $i, $(i+1)
    }
    print ""
}
$ awk -f tst.awk file
251=id1
223=author1
215=title1
230=year1
232=location1

251=id2
223=author2
230=year2
232=location2
215=title2

251=id3
230=year2
232=location2
215=title2

重新阅读您的问题后，这可能更接近您真正想要的：

$ cat tst.awk
BEGIN { FS="[<>]+"; OFS="," }

{
    for (i=2;i<NF;i+=3) {
        if (!seenName[$i]++) {
            names[++numNames] = $i
        }
        n2v[NR,$i] = $(i+1)
    }
}

END {
    for (nameNr=1; nameNr<=numNames; nameNr++) {
        printf "%s%s", names[nameNr], (nameNr<numNames?OFS:ORS)
    }

    for (recNr=1; recNr<=NR; recNr++) {
        for (nameNr=1; nameNr<=numNames; nameNr++) {
            name = names[nameNr]
            printf "%s%s", n2v[recNr,name], (nameNr<numNames?OFS:ORS)
        }
    }
}
$
$ awk -f tst.awk file
251,223,215,230,232
id1,author1,title1,year1,location1
id2,author2,title2,year2,location2
id3,,title2,year2,location2

如果没有，请更新您的问题，以根据您发布的输入显示您确实想要的实际输出。

【讨论】：