使用 TIdTcpClient 接收超时的部分数据

Question

如何使用 TIdTcpClient 接收具有以下条件的 100 字节字符串？：

• 如果什么都没有进来，Read 调用将被阻塞，线程将永远等待
• 如果收到 100 个字节，则 Read 调用应返回字节字符串
• 如果收到的字节数多于 0，但少于 100，则 Read 调用应在超时（例如 1 秒）后返回，以便在合理的时间内至少返回某些内容，而不会产生超时异常，因为 Delphi 中的异常处理IDE 的调试模式不方便。

我目前不是最优的代码如下：

unit Unit2;

interface

uses
  System.Classes, IdTCPClient;

type
  TTcpReceiver = class(TThread)
  private
    _tcpc: TIdTCPClient;
    _onReceive: TGetStrProc;
    _buffer: AnsiString;
    procedure _receiveLoop();
    procedure _postBuffer;
  protected
    procedure Execute(); override;
  public
    constructor Create(); reintroduce;
    destructor Destroy(); override;
    property OnReceive: TGetStrProc read _onReceive write _onReceive;
  end;

implementation

uses
  System.SysUtils, Vcl.Dialogs, IdGlobal, IdExceptionCore;

constructor TTcpReceiver.Create();
begin
  inherited Create(True);
  _buffer := '';
  _tcpc := TIdTCPClient.Create(nil);
  //_tcpc.Host := '192.168.52.175';
  _tcpc.Host := '127.0.0.1';
  _tcpc.Port := 1;
  _tcpc.ReadTimeout := 1000;
  _tcpc.Connect();
  Suspended := False;
end;

destructor TTcpReceiver.Destroy();
begin
  _tcpc.Disconnect();
  FreeAndNil(_tcpc);
  inherited;
end;

procedure TTcpReceiver.Execute;
begin
  _receiveLoop();
end;

procedure TTcpReceiver._postBuffer();
var buf: string;
begin
  if _buffer = '' then Exit;
  buf := _buffer;
  _buffer := '';
  if Assigned(_onReceive) then begin
    Synchronize(
      procedure()
      begin
        _onReceive(buf);
      end
    );
  end;
end;

procedure TTcpReceiver._receiveLoop();
var
  c: AnsiChar;
begin
  while not Terminated do begin
    try
      c := AnsiChar(_tcpc.IOHandler.ReadByte());
      _buffer := _buffer + c;
      if Length(_buffer) > 100 then
        _postBuffer();
    except
      //Here I have to ignore EIdReadTimeout in Delphi IDE everywhere, but I want just to ignore them here
      on ex: EIdReadTimeout do _postBuffer();
    end;
  end;
end;

end.

Answer 1

TCP 是面向流的，而不是像 UDP 那样面向消息的。在没有任何结构的情况下读取任意字节是糟糕的设计，如果您过早停止读取并且您想要读取的字节在您停止读取后到达，那么很容易破坏您的通信。字节在被读取之前不会从套接字中删除，因此下一次读取的字节数可能比预期的更多/不同。

如果您期望 100 个字节，那么只需读取 100 个字节并完成它。如果发送方只发送 50 个字节，它需要提前告诉你，这样你就可以在收到 50 个字节后停止读取。如果发件人不这样做，那么这是一个设计得很糟糕的协议。使用超时来检测传输结束通常是不好的设计。网络滞后很容易导致误检测。

TCP 消息应该有足够的框架，以便接收者准确地知道一条消息在哪里结束以及下一条消息从哪里开始。在 TCP 中有三种方法可以做到这一点：

1. 使用固定长度的消息。接收方可以继续读取，直到达到预期的字节数。

2. 在发送消息本身之前发送消息的长度。接收方可以先读取长度，然后继续读取，直到到达指定的字节数。

3. 使用不出现在消息数据中的唯一分隔符终止消息。接收方可以继续读取字节，直到该分隔符到达。

---

话虽如此，您所要求的可以在 TCP 中完成（但 不应该在 TCP 中完成！）。而且完全不用手动缓冲就可以完成，改用 Indy 的内置缓冲。例如：

unit Unit2;

interface

uses
  System.Classes, IdTCPClient;

type
  TTcpReceiver = class(TThread)
  private
    _tcpc: TIdTCPClient;
    _onReceive: TGetStrProc;
    procedure _receiveLoop;
    procedure _postBuffer;
  protected
    procedure Execute; override;
  public
    constructor Create; reintroduce;
    destructor Destroy; override;
    property OnReceive: TGetStrProc read _onReceive write _onReceive;
  end;

implementation

uses
  System.SysUtils, Vcl.Dialogs, IdGlobal;

constructor TTcpReceiver.Create;
begin
  inherited Create(False);
  _tcpc := TIdTCPClient.Create(nil);
  //_tcpc.Host := '192.168.52.175';
  _tcpc.Host := '127.0.0.1';
  _tcpc.Port := 1;
end;

destructor TTcpReceiver.Destroy;
begin
  _tcpc.Free;
  inherited;
end;

procedure TTcpReceiver.Execute;
begin
  _tcpc.Connect;
  try
    _receiveLoop;
  finally
    _tcpc.Disconnect;
  end;
end;

procedure TTcpReceiver._postBuffer;
var
  buf: string;
begin
  with _tcpc.IOHandler do
    buf := ReadString(IndyMin(InputBuffer.Size, 100));
  { alternatively:
  with _tcpc.IOHandler.InputBuffer do
    buf := ExtractToString(IndyMin(Size, 100));
  }
  if buf = '' then Exit;
  if Assigned(_onReceive) then
  begin
    Synchronize(
      procedure
      begin
        if Assigned(_onReceive) then
          _onReceive(buf);
      end
    );
  end;
end;

procedure TTcpReceiver._receiveLoop;
var
  LBytesRecvd: Boolean;
begin
  while not Terminated do
  begin
    while _tcpc.IOHandler.InputBufferIsEmpty do
    begin
      _tcpc.IOHandler.CheckForDataOnSource(IdTimeoutInfinite);
      _tcpc.IOHandler.CheckForDisconnect;
    end;

    while _tcpc.IOHandler.InputBuffer.Size < 100 do
    begin
      // 1 sec is a very short timeout to use for TCP.
      // Consider using a larger timeout...
      LBytesRecvd := _tcpc.IOHandler.CheckForDataOnSource(1000);
      _tcpc.IOHandler.CheckForDisconnect;
      if not LBytesRecvd then Break;
    end;

    _postBuffer;
  end;
end;

end.

---

顺便说一句，您所说的“Delphi IDE 的调试模式中的异常处理不方便”简直是荒谬的。 Indy 的IOHandler 具有用于控制异常行为的属性和方法参数，如果您不喜欢调试器处理异常的方式，那么只需将其配置为忽略它们。您可以将调试器配置为忽略特定的异常类型，也可以使用断点告诉调试器跳过处理特定代码块中的异常。