IP 黑名单 TcpServer

Question

如何限制每个 ip 的连接数？我已经尝试过此代码how to block unknown clients in indy (Delphi)，但如果我的服务器被淹没，我将无法连接。来自 Remy 的代码只是阻止 CPU 使用 100% 并使用更多内存。但是来自洪水的连接在 tcpserver 上仍然存在，我无法连接到服务器。所以我的问题是，我如何在 onconnect 之前限制连接，使用 tcpserver 接受一些东西？也许挂钩接受功能并尝试限制连接？

Answer 1

如何限制每个 ip 的连接数？

您已经知道答案了，因为这正是 the other code 正在做的事情。

如果我的服务器被淹没，我将无法连接。

其他代码的目的只是将客户端 IP 地址限制为最多 10 个同时连接，而不是防止泛滥或降低 CPU/RAM 使用率。除非您停用服务器或设置其MaxConnections 属性，否则您无法阻止不需要的客户端连接到您的服务器。除此之外，您所能做的就是尽快断开不需要的客户端，您可以在服务器的OnConnect 事件中执行此操作。但是如果你被淹没了，这将需要时间来处理，特别是如果你不断地锁定和解锁服务器的Contexts 列表，这最终将序列化服务器的内部线程。

洪水管理确实需要由防火墙或路由器/负载平衡器来处理，而不是在服务器应用程序本身中。如果这对您来说是不可接受的，那么至少仅在 Windows 上，一个选项可能是编写一个自定义的 TIdServerIOHandlerStack 派生组件，该组件覆盖虚拟 Accept() 方法来调用 WinSock 的 WSAAccept() 函数，它为您提供回调可以在连接离开接受队列之前拒绝连接，因此TIdTCPServer 不会看到它们。例如：

type
  TMyServerIOHandler = class(TIdServerIOHandlerStack)
  public
    function Accept(ASocket: TIdSocketHandle; AListenerThread: TIdThread; AYarn: TIdYarn): TIdIOHandler; override;
  end;

function MyConditionFunc(lpCallerId, lpCallerData: LPWSABUF; lpSQOS, lpGQOS: LPQOS; lpCalleeId, lpCalleeData: LPWSABUF; g: PGROUP dwCallbackData: DWORD_PTR): Integer; stdcall;
begin
  if (the address stored in lpCallerId is blocked) then
    Result := CF_REJECT
  else
    Result := CF_ACCEPT;
end;

type
  TIdSocketHandleAccess = class(TIdSocketHandle)
  end;

function TMyServerIOHandler.Accept(ASocket: TIdSocketHandle; AListenerThread: TIdThread; AYarn: TIdYarn): TIdIOHandler;
var
  LIOHandler: TIdIOHandlerSocket;
  LBinding: TIdSocketHandle;
  LAcceptedSocket: TIdStackSocketHandle;
begin
  Result := nil;
  LIOHandler := TIdIOHandlerStack.Create(nil);
  try
    LIOHandler.Open;
    while not AListenerThread.Stopped do
    begin
      if ASocket.Select(250) then
      begin
        LBinding := LIOHandler.Binding;
        LBinding.Reset;
        LAcceptedSocket := WSAAccept(ASocket.Handle, nil, nil, @MyConditionFunc, 0);
        if LAcceptedSocket <> Id_INVALID_SOCKET then
        begin
          TIdSocketHandleAccess(LBinding).SetHandle(LAcceptedSocket);
          LBinding.UpdateBindingLocal;
          LBinding.UpdateBindingPeer;
          LIOHandler.AfterAccept;
          Result := LIOHandler;
          LIOHandler := nil;
          Break;
        end;
      end;
    end;
  finally
    FreeAndNil(LIOHandler);
  end;
end;

然后您可以在激活服务器之前将TMyServerIOHandler 的实例分配给TIdTCPServer.IOHandler 属性。