带有或的平均值

Question

我已经读到这可能是不可能的/我只是做错了，所以我想知道是否有人知道解决方法（非 VBA）或可以纠正我？谢谢！

Col A has the price of apples and oranges
Col D has apples and Oranges
Col E has the type of fruit (Red, Yellow, Green, Purple)

我正在尝试获取 Col A 的平均值，其中 Col D 是苹果，而 Col E 是红色或黄色。

我试过了：

=SUM(AVERAGEIFS(A:A,D:D,"Apples",E:E,"Red"),AVERAGEIFS(A:A,D:D,"Apples",E:E,"Yellow"))/2

但它不起作用 - 有人有什么想法吗？

Answer 1

是的，您可以这样做：

=SUM(SUMIFS(A:A,D:D,"Apples",E:E,{"Red","Yellow"}))/SUM(COUNTIFS(D:D,"Apples",E:E,{"Red","Yellow"}))

与Enter确认

编辑 公式比较

1) 在第一个屏幕截图中，所有结果看起来都相似：

2) 在第二个屏幕截图中，我将单元格 E8 更改为紫色。结果开始不同：

3) 在第三个屏幕截图中，很明显在使用 SUM/COUNTIFS 时没有使用 AVERAGE 的结果：

Answer 2

我认为你不能在 AVERAGEIFS 中添加 OR 操作，但你可以使用它（这是一个数组公式，所以你必须使用 ctrl + shift + enter 输入它）：

=AVERAGE(IF((D:D="Apples")*((E:E="Yellow")+ (E:E="Red")),A:A))

如果您不想使用数组公式（作为@JvdV 答案的替代方案），您可以使用：

=SUMPRODUCT(A:A,--(D:D="Apples"), --((E:E="Red")+(E:E="Yellow")))/SUMPRODUCT(--(D:D="Apples"), --((E:E="Red")+(E:E="Yellow")))

Answer 3

和JvdV的回复类似，可以直接使用AVERAGEIFS。

=AVERAGE(AVERAGEIFS(A:A, B:B, {"a","c"}))
'for your data
=AVERAGE(AVERAGEIFS(A:A,D:D, "Apples", E:E, {"Red","Yellow"}))

附录：

4.00            apples  Red
2.70            oranges Purple
2.13            apples  Purple
2.64            apples  Yellow
3.11            apples  Purple
2.96            apples  Purple
9.44            apples  Yellow
2.07            oranges Red
3.14            oranges Purple
3.58            oranges Yellow
2.44            oranges Red
2.82            apples  Red
2.86            apples  Yellow
2.23            oranges Yellow
1.95            apples  Red
2.37            oranges Yellow

上述样本数据产生以下相同的结果：

=AVERAGE(A2,A5,A8,A13,A14,A16)
=AVERAGE(AVERAGEIFS(A:A,D:D,"apples",E:E,{"red","yellow"}))
=SUM(SUMIFS(A:A, D:D, "apples", E:E, {"red","yellow"}))/SUM(COUNTIFS(D:D, "apples", E:E, {"red","yellow"}))

但是，当 { OR } 条件中有不同数量的匹配项时，就会出现错误的结果。

4.00            apples  Red
2.70            oranges Purple
2.13            apples  Purple
2.64            apples  Yellow
3.11            apples  Purple
2.96            apples  Purple
9.44            apples  Yellow
2.07            apples  Red
3.14            oranges Purple
3.58            oranges Yellow
2.44            oranges Red
2.82            apples  Red
2.86            apples  Yellow
2.23            oranges Yellow
1.95            apples  Red
2.37            oranges Yellow