Visual Basic 替换不起作用

Question

我正在编写一个简单的刽子手程序，我想替换我的变量中的一些内容，该变量存储已找到的单词的字母。

代码如下：

    Replace(wordLettersFound, Mid(wordLettersFound, counter, 1), letter)

wordLettersFound、counter 和 letter 是我使用的 3 个变量。

这个脚本前面的变量都是下划线，但是没有变化！谁能帮我解决这个问题？

附： 我不知道我使用的是什么版本的 VB，Visual Studio Community 2015 只是说“Visual Basic”。

Answer 1

Replace 不会修改字符串，而是返回一个带有替换的新字符串，因此您应该将其分配给变量：

wordLettersFound = Replace(wordLettersFound, Mid(wordLettersFound, counter, 1), letter)

Answer 2

另一种替换方式，

    Dim theLetters As String = "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyzAAA"

    theLetters = theLetters.Replace("A"c, "@"c)

Answer 3

还有另一种方法可以替换字符串中的字符。在您的情况下，使用 Replace 函数有点尴尬，因为在开始时，all 字符都是下划线 - 使用时替换会将所有字符替换为找到的字符。

相反，您可以将字符串剪切到所需替换左侧的部分，添加替换字符，然后添加字符串的其余部分。该行是此代码中注释“将 foundWord 切起来并将字符放在正确的位置”之后的行：

Module Module1

    Sub Main()
        Dim wordToFind = "alphabet"
        ' make a string of dashes the same length as the word to find
        Dim foundWord = New String("-"c, wordToFind.Length)

        While foundWord <> wordToFind
            Console.Write("Enter your guess for a letter: ")

            Dim guess = Console.ReadLine()
            ' make sure the user has only entered one character
            If guess.Length = 1 Then
                ' see if the letter is in the string
                Dim pos = wordToFind.IndexOf(guess)
                While pos >= 0
                    ' chop foundWord up and put the character in the right place
                    foundWord = foundWord.Substring(0, pos) & guess & foundWord.Substring(pos + 1)
                    ' see if there are any more of the same letter
                    pos = wordToFind.IndexOf(guess, pos + 1)
                End While

                ' show the user the current progress
                Console.WriteLine(foundWord)
            Else
                Console.WriteLine("Please enter just one letter!")
            End If

        End While

        Console.WriteLine("You did it!")

        Console.WriteLine("Press enter to leave the program.")
        Console.ReadLine()

    End Sub

End Module

注意不要将所有这些代码直接用于家庭作业，因为您的老师会找到它。这也适用于其他做家庭作业的人——你知道自己是谁；）