表单选项按钮 Excel VBA 不工作

Question

我正在尝试使用多个表单选项按钮，如下面的代码所示。目标是从一列复制一系列数据并将它们和值粘贴到另一列中。没有什么花哨。所以，我有多个选项按钮和一个命令按钮，即 Button38。当我运行代码时，我没有收到错误消息并且它不起作用。任何帮助将不胜感激，我也是 VBA 的新手。

Sub Button38_Click()
Application.ScreenUpdating = False
Sheets("Sheet2").Visible = True
Sheets("Sheet2").Select

If OptionButton22 = True Then
Range("AI2:AI182").Copy
Range("AK2:AK182").PasteSpecial Paste:=xlPasteAllUsingSourceTheme, Operation:=xlNone _
        , SkipBlanks:=False, Transpose:=False

ElseIf OptionButton23 = True Then
Range("AD2:AD182").Copy
Range("AK2:AK182").PasteSpecial Paste:=xlPasteAllUsingSourceTheme, Operation:=xlNone _
        , SkipBlanks:=False, Transpose:=False

ElseIf OptionButton24 = True Then
Range("AE2:AE182").Copy
Range("AK2:AK182").PasteSpecial Paste:=xlPasteAllUsingSourceTheme, Operation:=xlNone _
        , SkipBlanks:=False, Transpose:=False

End If
Sheets("Sheet1").Select
Sheets("Sheet2").Visible = False
Application.ScreenUpdating = True
End Sub

Answer 1

我将所有内容重新设置为 Sheet1 和 sheet2。 Sheet1 是具有表单选项按钮的那个，而 sheet2 具有列。我希望 sheet2 一直隐藏。

您正在使用表单控件（选项按钮）。此外，您不需要取消隐藏/隐藏工作表。让它保持隐藏。此代码将起作用，即使 Sheet2 被隐藏，该范围也会被复制粘贴。

这是你正在尝试的吗？

Sub Button38_Click()
    Dim wsThis As Worksheet, wsThat As Worksheet
    Dim sCol As String

    Set wsThis = Sheet2 '<~~ This sheet has the range
    Set wsThat = Sheet1 '<~~ This sheet has FORM option buttons

    With wsThis
        If wsThat.Shapes("Option Button 22").OLEFormat.Object.Value = 1 Then sCol = "AI"
        If wsThat.Shapes("Option Button 23").OLEFormat.Object.Value = 1 Then sCol = "AD"
        If wsThat.Shapes("Option Button 24").OLEFormat.Object.Value = 1 Then sCol = "AE"

        .Range(sCol & "2:" & sCol & "182").Copy

        .Range("AK2:AK182").PasteSpecial Paste:=xlPasteAllUsingSourceTheme, _
        Operation:=xlNone, SkipBlanks:=False, Transpose:=False
    End With
End Sub

Answer 2

如果您将所有对象限定为它们的父对象，则代码应该可以工作。见下文。 （我还对代码进行了一些重构，使其更简洁、更易于维护/阅读并且更短）。

Sub Button38_Click()

Dim ws1 as Worksheet
Set ws1 = Worksheets("Sheet1")

Application.ScreenUpdating = False

With Sheet2 'using the VBA sheet object name (change if needed)

    .Visible = xlSheetVisible

    Dim sCol As String

    If .OptionButton22 = True Then
        sCol = "AI"
    ElseIf .OptionButton23 = True Then
        sCol = "AD"
    ElseIf .OptionButton24 = True Then
        sCol = "AE"
    End If

   .Visible = xlSheetHidden

End With

ws1.Range("AK2:AK182").Value = ws1.Range(sCol & "2:" & sCol & "182").Value

'if you need the range theme copied as well use the code below
 'With ws1
    '.Range(sCol & "2:" & sCol & "182").Copy
    '.Range("AK2:AK182").PasteSpecial Paste:=xlPasteAllUsingSourceTheme, Operation:=xlNone _
    , SkipBlanks:=False, Transpose:=False
 'End With

End Sub