首先，您应该注意 Excel 2013 之前的 Excel 没有内置的位运算符或函数（即使操作数是数字，Excel 的 OR() 函数也是逻辑的）。 Excel 2013 终于添加了这个明显缺失的功能。
使用 VBA
最简单的方法是创建一个用户定义函数来完成它。如果您准备好使用十进制输出、辅助列或非常重复的连接公式，则公式可以工作，但 VBA 可以解决这些限制 - 如果您能够在工作簿中包含代码，我建议您使用它。
十进制输入，十进制输出
以下示例仅公开了内置的按位运算符，可用作 Excel 公式中的函数。我假设是整数类型，尽管您可以将其更改为接受小数等。
您可以使用 Excel 内置的 BIN2DEC() 函数将字符串二进制数（例如“1010”）转换为小数（上例中为 10），尽管这只处理 9 位 + 符号位，或者您可以使用数组公式为您转换它（请参阅下面的“使用公式”部分）。
Public Function BITWISE_OR(operand1, operand2)
BITWISE_OR = CLng(operand1) Or CLng(operand2)
End Function
Public Function BITWISE_AND(operand1, operand2)
BITWISE_AND = CLng(operand1) And CLng(operand2)
End Function
Public Function BITWISE_XOR(operand1, operand2)
BITWISE_XOR = CLng(operand1) Xor CLng(operand2)
End Function
将数字结果转换回二进制字符串对于公式来说非常烦人 - 如果您需要的范围超过 Excel 内置的 DEC2BIN()（微不足道的 -512 到 +511）函数所涵盖的范围，那么我建议您使用 VBA （见下文），或使用列或行逐位构建二进制字符串（请参阅下面的“使用公式”部分）。
二进制字符串输入，二进制字符串输出
下面的内容本质上是遍历一个字符串，根据输入字符串中的相应位依次设置每个位。它使用Mid$ 语句就地对字符串执行位更改。位串可以是任意长度。
下面看起来很复杂，但实际上是相同的基本内容，对 And、Or 和 XOr 重复 3 次。
'str1, str2: the two bit strings. They can be different lengths.
'significantDigitsAreLeft: optional parameter to dictate how different length strings should be padded. Default = True.
Public Function Bitstr_AND(str1 As String, str2 As String, Optional significantDigitsAreLeft As Boolean = True)
Dim maxLen As Long, resStr As String, i As Long
If Len(str1) > Len(str2) Then maxLen = Len(str1) Else maxLen = Len(str2) 'get max length of the two strings
str1 = getPaddedString(str1, maxLen, significantDigitsAreLeft) 'pad left or right to the desired length
str2 = getPaddedString(str2, maxLen, significantDigitsAreLeft) 'pad left or right to the desired length
resStr = String$(maxLen, "0") 'prepare the result string into memory (Mid$ can operate without creating a new string, for performance)
For i = 1 To maxLen
If Mid$(str1, i, 1) = "1" And Mid$(str2, i, 1) = "1" Then
Mid$(resStr, i, 1) = "1" 'in-place overwrite of the existing "0" with "1"
End If
Next i
Bitstr_AND = resStr
End Function
'For explanatory comments, see Bitstr_AND
Public Function Bitstr_OR(str1 As String, str2 As String, Optional significantDigitsAreLeft As Boolean = True)
Dim maxLen As Long
Dim resStr As String
Dim i As Long
If Len(str1) > Len(str2) Then maxLen = Len(str1) Else maxLen = Len(str2)
str1 = getPaddedString(str1, maxLen, significantDigitsAreLeft)
str2 = getPaddedString(str2, maxLen, significantDigitsAreLeft)
resStr = String$(maxLen, "0")
For i = 1 To maxLen
If Mid$(str1, i, 1) = "1" Or Mid$(str2, i, 1) = "1" Then
Mid$(resStr, i, 1) = "1"
End If
Next i
Bitstr_OR = resStr
End Function
'For explanatory comments, see Bitstr_AND
Public Function Bitstr_XOR(str1 As String, str2 As String, Optional significantDigitsAreLeft As Boolean = True)
Dim maxLen As Long
Dim resStr As String
Dim i As Long
If Len(str1) > Len(str2) Then maxLen = Len(str1) Else maxLen = Len(str2)
str1 = getPaddedString(str1, maxLen, significantDigitsAreLeft)
str2 = getPaddedString(str2, maxLen, significantDigitsAreLeft)
resStr = String$(maxLen, "0")
For i = 1 To maxLen
If Mid$(str1, i, 1) = "1" Then
If Not Mid$(str2, i, 1) = "1" Then
Mid$(resStr, i, 1) = "1"
End If
ElseIf Mid$(str2, i, 1) = "1" Then 'Save an If check by assuming input string contains only "0" or "1"
Mid$(resStr, i, 1) = "1"
End If
Next i
Bitstr_XOR = resStr
End Function
'Helper to pad string
Private Function getPaddedString(str As String, length As Long, padLeft As Boolean) As String
If Len(str) < length Then
If padLeft Then
getPaddedString = String$(length - Len(str), "0") & str
Else
getPaddedString = str & String$(length - Len(str), "0")
End If
Else
getPaddedString = str
End If
End Function
使用公式
您可以使用 Text 函数或 Sumproduct 进行 XOR 运算。如果您不想使用 VBA，这可能更合适，但公式很难确保涵盖所有情况，例如否定或不同长度的二进制字符串。关于使用 Sumproduct 的示例，我推荐您参考出色的博客文章 http://www.excelhero.com/blog/2010/01/5-and-3-is-1.html，以及使用文本函数的示例 http://chandoo.org/wp/2011/07/29/bitwise-operations-in-excel/。
我编写了自己的公式来处理某些情况，并在下面解释它们以指导您。
二进制字符串输入，十进制输出
在下文中，A2 和 B2 指的是最多 32 位字符串形式的两个二进制数。字符串可以是可变长度，因为公式将用 0 填充到必要的长度。如何将其增加到更多位应该很明显。它们必须使用 Ctrl+Shift+Enter 输入。
最重要的位在左边。为了让它的最低有效位在左边，你可以去掉 2 部分的幂中的小减法，并让它向右填充。
位与：
=SUM((((MID(REPT("0",32-LEN($A$2))&$A$2,ROW($1:$32),1)="1")+(MID(REPT("0",32-LEN($B$2))&$B$2,ROW($1:$32),1)="1"))=2)*(2^(32-ROW($1:$32))))
按位或：
=SUM((((MID(REPT("0",32-LEN($A$2))&$A$2,ROW($1:$32),1)="1")+(MID(REPT("0",32-LEN($B$2))&$B$2,ROW($1:$32),1)="1"))>0)*(2^(32-ROW($1:$32))))
按位异或：
=SUM((((MID(REPT("0",32-LEN($A$2))&$A$2,ROW($1:$32),1)="1")+(MID(REPT("0",32-LEN($B$2))&$B$2,ROW($1:$32),1)="1"))=1)*(2^(32-ROW($1:$32))))
二进制字符串输入，二进制字符串输出
单个单元格的解决方案会很费力，因为 Excel 中没有数组连接公式。您可以使用 CONCATENATE 函数将每个位粘合在一起，每个位都是 If 比较每个二进制字符串的结果，相应地返回 1 或 0。正如我所说，虽然很容易（只需像 =IF(Mid(A1,1,1) = "1",...) 那样构建它，这会很无聊，所以我个人不会为你做；）
或者，您可以更简单地使用列或行来构建字符串，例如：
如果 A1 和 B1 有您的二进制字符串，则在 C1 中放入（对于 AND，或对于 OR，将末尾的 =2 更改为 >0，对于 XOR，将其更改为 =1）：
=IF((MID($A1,1,1)="1")+(MID($B1,1,1)="1"))=2,"1","0")
然后在 D1 中放：
=C1 & IF((MID($A1,COLUMN()-COLUMN($C1),1)="1")+(MID($B1,COLUMN()-COLUMN($C1),1)="1"))=2,"1","0")
然后将它拖到尽可能多的列中