如何从文件中获取每一行的数据？

Question

在这里，我想将每行中的数据打印为 3 个单独的值，并以“:”作为分隔符。文件BatmanFile.txt 有以下详细信息：

Bruce:Batman:bat@bat.com
Santosh:Bhaskar:santosh@santosh.com

我预期的输出是：

Bruce
Batman
bat@bat.com
Santosh
Bhaskar
santosh@santosh.com

执行脚本后的输出为：

Bruce
Batman
bat@bat.com
Bruce
Batman
bat@bat.com

请解释一下我在这里缺少什么：

use strict;
use warnings;

my $file = 'BatmanFile.txt';
open my $info, $file or die "Could not open $file: $!";
my @resultarray;
while( my $line = <$info>)  {   
    #print $line;    
    chomp $line;
    my @linearray = split(":", $line);
    push(@resultarray, @linearray);
    print join("\n",$resultarray[0]),"\n";
    print join("\n",$resultarray[1]),"\n";
    print join("\n",$resultarray[2]),"\n";
}
close $info;

Answer 1

您正在逐行循环文件。您已将所有行（拆分后）存储在一个数组中。循环完成后，您将拥有 resultarray 数组中的所有数据，只需在循环后打印整个数组（而不是仅打印您目前正在执行的前 3 个索引）。

#!/usr/bin/perl
use strict;
use warnings;
my @resultarray;
while( my $line = <DATA>){
    chomp $line;
    my @linearray = split(":", $line);
    push @resultarray, @linearray;
}
print "$_\n" foreach @resultarray;
__DATA__
Bruce:Batman:bat@bat.com
Santosh:Bhaskar:santosh@santosh.com

Demo

---

您可以避免所有变量并执行以下操作

while(<DATA>){
    chomp;
    print "$_\n" foreach split(":");
}

---

一个班轮：

perl -e 'while(<>){chomp; push @result, split(":",$_);} print "$_\n" foreach @result' testdata.txt

Answer 2

当你这样做时：

push(@resultarray, @linearray);

你最后将@linearray推入@resultarray，所以索引0到2仍然是你第一次推@linearray时的项目。

要用第二次迭代的值覆盖@resultarray，请执行以下操作：

@resultarray = @linearray;

改为。

或者，使用unshift 将@linearray 放在@resultarray、as suggested by Sobrique 的开头：

unshift @resultarray, @linearray;

Answer 3

所以，您只想将transliterate : 转为\n？

$ perl -pe 'tr/:/\n/' data.txt

输出：

Bruce
Batman
bat@bat.com
Santosh
Bhaskar
santosh@santosh.com

Answer 4

use strict;
use warnings;

my $file = 'BatmanFile.txt';
open my $info, $file or die "Could not open $file: $!";
my @resultarray;
while( my $line = <$info>)  {   

    #print $line;    
    chomp $line;
    my @linearray = split(":", $line);
    #push(@resultarray, @linearray);
    print join("\n",$linearray[0]),"\n";
    print join("\n",$linearray[1]),"\n";
    print join("\n",$linearray[2]),"\n";

}
close $info;