如何使用 For/Next 循环根据复选框状态打印范围

Question

我无法将一些代码放在一起，这些代码允许我查看复选框的状态并在复选框等于 true 时在另一个工作表上打印指定范围，然后针对给定数量的复选框重复该循环，并且范围。

我正在使用两个不同的 For - Next 循环来尝试完成这项任务。以下是我当前的代码。

Sub PrintGraphs()
Dim i As Integer
Dim r As Integer
    For i = 16 To 18
        If ActiveSheet.OLEObjects("CheckBox" & i).Object.Value = True Then
            For r = 1 To 3
                Worksheets("Cut Tables Graphs").Activate
                    Range("RangeSet" & r).Select
                    ActiveSheet.PageSetup.PrintArea = ("RangeSet" & r)
                    With ActiveSheet.PageSetup
                        .PaperSize = xlPaperLetter
                        .Orientation = xlLandscape
                        .Zoom = False
                        .FitToPagesWide = 1
                        .FitToPagesTall = 1
                        .LeftMargin = Application.InchesToPoints(0.25)
                        .RightMargin = Application.InchesToPoints(0.25)
                        .TopMargin = Application.InchesToPoints(0.25)
                        .BottomMargin = Application.InchesToPoints(0.25)
                        .CenterHorizontally = True
                        .CenterVertically = True
                    End With
                    Application.PrintCommunication = True
                    Selection.PrintOut Copies:=1, Collate:=True
            Next r
        End If
    Next i
End Sub

我还在一个单独的模块上使用公共常量来定义变量“RangeSet”。该模块上的代码如下。

Public Const RangeSet1 = "B2:U51"
Public Const RangeSet2 = "W2:AP51"
Public Const RangeSet3 = "B53:U102"

我希望我的代码查看复选框 16 到 18，然后打印复选框值等于 true 的相应范围。

期望的结果：

如果复选框 #16 等于 true，则打印范围“B2:U51”，否则 Next i

如果复选框 #17 等于 true，则打印范围“W2:AP51”，否则 Next i

如果复选框 #18 为真，则打印范围“B53:U102”，否则结束循环

我目前遇到的错误是：运行时错误'1004'：在包含“Range("RangeSet" & r).Select 的行上的调用目标已引发异常。选择

我们将不胜感激任何有关找到解决此问题的方法的帮助。提前谢谢你。

Answer 1

我觉得最简单的方法是创建一个包含您要记录的值的数组。填充完数组后，您可以使用 for 循环将其打印到您想要的任何位置。

Answer 2

Range("RangeSet" & r).Select

不是 VBA 中的有效范围。你将把它传递给“RangeSet1”，因为它不是一个范围，也不是你声明的变量。

可以试试

if r = 1 then
     Range(RangeSet1).Select
elseif r=2 then
     Range(RangeSet2).Select
elseif r=3 then
     Range(RangeSet3).Select
else
    stop'should never get here?
endif

有一种方法可以在一行代码中做到这一点，但我不记得它的语法了。

Answer 3

这就是我编写代码的方式

Sub PrintGraphs()

    Dim i As Integer

    With ThisWorkbook.Worksheets("Cut Tables Graphs")
        With .PageSetup
            .PaperSize = xlPaperLetter
            .Orientation = xlLandscape
            .Zoom = False
            .FitToPagesWide = 1
            .FitToPagesTall = 1
            .LeftMargin = Application.InchesToPoints(0.25)
            .RightMargin = Application.InchesToPoints(0.25)
            .TopMargin = Application.InchesToPoints(0.25)
            .BottomMargin = Application.InchesToPoints(0.25)
            .CenterHorizontally = True
            .CenterVertically = True
        End With
        Application.PrintCommunication = True
        For i = 16 To 18
            If .OLEObjects("CheckBox" & i).Object.Value = True Then

                .Range(Choose(i - 15, RangeSet1, RangeSet2, RangeSet3)).PrintOut Copies:=1, Collate:=True

            End If
        Next i
    End With

End Sub

不需要变量 r - 如果您选择 CheckBox16，您想打印范围 1 - 因此从 i 中删除 15 并得到 1 - 选择该范围（希望有意义）。

我还假设“ActiveSheet”（带有复选框的那个）是“Cut Tables Graphs”。

我在底部包含了您的原始代码和一些 cmets。

Sub PrintGraphs()
Dim i As Integer
Dim r As Integer
    'This will work - providing the correct sheet is active.
    For i = 16 To 18
        If ActiveSheet.OLEObjects("CheckBox" & i).Object.Value = True Then

            'This will cycle through all three no matter which checkbox was ticked.
            For r = 1 To 3

                'No need to activate the sheet.  Especially if it's the ActiveSheet.
                Worksheets("Cut Tables Graphs").Activate

                    'No need to select a range before working on it.
                    Range("RangeSet" & r).Select

                    'This only needs doing once - not at all if it's the default anyway.
                    'As it's inside the 1 to 3 loop it will happen 3 times.
                    ActiveSheet.PageSetup.PrintArea = ("RangeSet" & r)
                    With ActiveSheet.PageSetup
                        .PaperSize = xlPaperLetter
                        .Orientation = xlLandscape
                        .Zoom = False
                        .FitToPagesWide = 1
                        .FitToPagesTall = 1
                        .LeftMargin = Application.InchesToPoints(0.25)
                        .RightMargin = Application.InchesToPoints(0.25)
                        .TopMargin = Application.InchesToPoints(0.25)
                        .BottomMargin = Application.InchesToPoints(0.25)
                        .CenterHorizontally = True
                        .CenterVertically = True
                    End With
                    Application.PrintCommunication = True

                    'Rather than select the range and print the selection,
                    'just reference the range and print it.
                    Selection.PrintOut Copies:=1, Collate:=True
            Next r
        End If
    Next i
End Sub