在 PL/SQL 中使用带有动态 SELECT INTO 子句的绑定变量

Question

我有一个关于在 PL/SQL 的动态 SQL 语句中可以在何处使用绑定变量的问题。

例如，我知道这是有效的：

CREATE OR REPLACE FUNCTION get_num_of_employees (p_loc VARCHAR2, p_job VARCHAR2) 
RETURN NUMBER
IS
  v_query_str VARCHAR2(1000);
  v_num_of_employees NUMBER;
BEGIN
  v_query_str := 'SELECT COUNT(*) FROM emp_' 
                 || p_loc
                 || ' WHERE job = :bind_job';                           
  EXECUTE IMMEDIATE v_query_str
    INTO v_num_of_employees
    USING p_job;
  RETURN v_num_of_employees;
END;
/

我想知道你是否可以在这样的选择语句中使用绑定变量

CREATE OR REPLACE FUNCTION get_num_of_employees (p_loc VARCHAR2, p_job VARCHAR2) 
RETURN NUMBER
IS
  v_query_str VARCHAR2(1000);
  v_num_of_employees NUMBER;
BEGIN
  v_query_str := 'SELECT COUNT(*) INTO :into_bind FROM emp_' 
                 || p_loc
                 || ' WHERE job = :bind_job';                           
  EXECUTE IMMEDIATE v_query_str
    USING out v_num_of_employees, p_job;
  RETURN v_num_of_employees;
END;
/

注意，我使用 SELECT INTO 语句作为动态字符串，并在 INTO 子句中使用了绑定变量。

我现在正在旅行，几天之内将无法在家中使用我的电脑，但这一直困扰着我。尝试阅读 PL/SQL 参考，但他们没有这样的选择示例。

谢谢

Answer 1

Select Into 功能仅适用于 PL/SQL Block，当您使用 Execute immediate 时，oracle 将 v_query_str 解释为 SQL Query 字符串，因此您不能使用 into 。将获得关键字丢失异常。 在示例 2 中，我们使用 begin end；所以它变成了 pl/sql 块并且它是合法的。

Answer 2

绑定变量可以在带有“in”子句的Oracle SQL查询中使用。

在 10g 中工作；其他版本不知道。

绑定变量是 varchar，最多 4000 个字符。

示例：绑定包含逗号分隔值列表的变量，例如

:bindvar = 1,2,3,4,5

select * from mytable
  where myfield in
    (
      SELECT regexp_substr(:bindvar,'[^,]+', 1, level) items
      FROM dual
      CONNECT BY regexp_substr(:bindvar, '[^,]+', 1, level) is not null
    );

（与我在此处发布的相同信息：How do you specify IN clause in a dynamic query using a variable?）

Answer 3

不，您不能那样使用绑定变量。在您的第二个示例中，v_query_str 中的:into_bind 只是变量v_num_of_employees 的值的占位符。您的 select into 语句将变成如下内容：

SELECT COUNT(*) INTO  FROM emp_...

因为v_num_of_employees 的值是null EXECUTE IMMEDIATE。

您的第一个示例展示了将返回值绑定到变量的正确方法。

编辑

原始海报编辑了我在回答中提到的第二个代码块，以使用 v_num_of_employees 的 OUT 参数模式而不是默认的 IN 模式。此修改使两个示例在功能上等效。

Answer 4

在我看来，动态 PL/SQL 块有些晦涩难懂。虽然非常灵活，但也难以调整、难以调试并且难以弄清楚发生了什么。 我的投票投给你的第一个选项，

EXECUTE IMMEDIATE v_query_str INTO v_num_of_employees USING p_job;

两者都使用绑定变量，但首先，对我来说，它比 @jonearles 选项更可重用和可调整。

Answer 5

将 select 语句放在动态 PL/SQL 块中。

CREATE OR REPLACE FUNCTION get_num_of_employees (p_loc VARCHAR2, p_job VARCHAR2) 
RETURN NUMBER
IS
  v_query_str VARCHAR2(1000);
  v_num_of_employees NUMBER;
BEGIN
  v_query_str := 'begin SELECT COUNT(*) INTO :into_bind FROM emp_' 
                 || p_loc
                 || ' WHERE job = :bind_job; end;';
  EXECUTE IMMEDIATE v_query_str
    USING out v_num_of_employees, p_job;
  RETURN v_num_of_employees;
END;
/