颜色数据透视表数据取决于列标题与行数据相比

Question

我有一个数据透视表，其中没有天数作为列，类别作为行，

编辑：-我想强调 4 个条件

1. 所有符合在线条件且等于 2 天的值（一种颜色为“橙色”）
2. 所有符合在线条件且超过 2 天的值（用一种颜色“红色”表示）
3. 任何标题下超过 5 天的所有单元格（另一种颜色“黄色”）
4. 只要标题超过 5 天，标题本身就会以“黄色”突出显示

因此我想根据列值突出显示单元格值（基于大于 6 天的条件） 和行值（突出显示在线的行）

这可能吗？在 vba 或 excel 中？？

我想要的输出如下。

Answer 1

理想情况下，您首先自己尝试一下，我们会帮助您修复您的代码，但是因为这对我来说是一个有用的练习......

Sub Tester()

    Dim pt As PivotTable, pf As PivotField, pi As PivotItem, d, clr As Long
    Dim rngTwoDays As Range, rngFiveDays As Range, rwOnline As Range, c As Range
    
    Set pt = ActiveSheet.PivotTables(1)
    pt.TableRange1.Interior.ColorIndex = xlNone 'uncolor
    
    'some code for figuring out what's what in terms of ranges etc
    Debug.Print "*** Row Fields ***"
    PrintInfo pt.RowFields
    Debug.Print "*** Column Fields***"
    PrintInfo pt.ColumnFields
    'done figuring out...
    
    'Start coloring
    
    ' x days labels >=5days
    Set pf = pt.PivotFields("WC")
    For Each pi In pf.PivotItems
        d = Val(pi.Name) 'days number only
        If d >= 5 Then pi.LabelRange.Resize(2).Interior.Color = vbYellow
        If d = 5 Then Set rngFiveDays = pi.DataRange 'for next block
        If d = 2 Then Set rngTwoDays = pi.DataRange  'for next block
    Next pi
    
    'the rest
    Set pf = pt.PivotFields("Order Category")
    For Each pi In pf.PivotItems
        For Each c In pi.DataRange.Cells
            If c.Value > 0 Then
                clr = -1 'reset
                Select Case pi.Name
                    Case "Online"
                        If c.Column >= rngTwoDays.Column Then
                            clr = IIf(Not Application.Intersect(c, rngTwoDays) Is Nothing, _
                                      XlRgbColor.rgbOrange, vbRed)
                        End If
                    Case Else
                        If c.Column >= rngFiveDays.Column Then clr = vbYellow
                End Select
                If clr > -1 Then c.Interior.Color = clr
            End If
        Next c
    Next pi
End Sub

'utility sub for printing field information
Sub PrintInfo(fldsCol As Object)
    Dim pf As PivotField, pi As PivotItem
    For Each pf In fldsCol
        Debug.Print pf.Position, pf.Name
        For Each pi In pf.PivotItems
            Debug.Print , pi.Position, pi.Name, pi.LabelRange.Address, pi.DataRange.Address
        Next pi
    Next pf
End Sub