确定打印页面中的列数

Question

在 Excel 2007 中，我有一个工作表，其中仅包含几个单元格中的数据（正好在一页宽/高之内）。举例来说，假设工作表仅包含单元格 A1 中的数据。如何使用 VBA 确定适合单个打印页面的列数？换句话说，我如何确定最右边的列，我可以在其中添加数据而不导致打印额外的工作表。几个额外的 cmets：

• 我没有设置打印区域。如果我是，那我就用同样的 范围...但我不是。

• 我不能使用UsedRange，因为使用的范围比 实际适合打印页面的宽度/高度。

• 我不能使用ActiveWindow.VisibleRange，因为它不限于 单页宽度/高度。

我已经搜索和搜索，但找不到完成这个看似简单的任务的解决方案。我主要发现涉及UsedRange、VisibleRange 和打印区域的场景，但这些对我没有帮助。

编辑

这是我正在使用的函数的最终版本，对所选答案稍作调整。

Public Function GetLastColumnBeforeVPageBreak( _
        ByRef ws As Worksheet, _
        ByVal aVPageBreakNum As Long) As Long
    Dim isMod As Boolean

    isMod = False

    On Error GoTo ErrorHandler

    GetLastColumnBeforeVPageBreak = ws.VPageBreaks(aVPageBreakNum).Location.Column - 1

    ' If necessary, delete the last column with dummy data and reset UsedRange.
    If isMod Then
        ws.Cells(ws.Rows.Count, ws.Columns.Count).EntireColumn.Delete
        r = ws.UsedRange.Rows.Count
    End If

    Exit Function
ErrorHandler:
    If Err.Number = 9 Then
        ' Subscript out of range.
        ' Ensure there is more than one page by putting something in last cell.
        isMod = True
        ws.Cells(ws.Rows.Count, ws.Columns.Count).Value = 1
        Err.Clear
        Resume
    Else
        Err.Raise Err.Number
    End If
End Function

Answer 1

我确定分页符周围有一个工作表属性，所以我在 IDE 中按 F2 打开对象浏览器并在 pagebreak 上搜索。一点点 F1 显示有一个 Worksheets(1).VPageBreaks(1).Location 属性返回一个范围对象。范围的左侧与第一个垂直分页符对齐，因此：

LastColOnP1 = Worksheets(1).VPageBreaks(1).Location.Column - 1

将为您提供一个变量，其中包含将在第一张纸的第 1 页上打印的最后一列的编号。

或者在一个过程中：

Sub FindFirstVPageBreak()
Dim LastColOnP1 As Long

With ActiveSheet
    'Ensure there is more than one page by puting something in last column
    .Cells(1, .Columns.Count) = 1
    LastColOnP1 = .VPageBreaks(1).Location.Column - 1
    'Delete the last column to allow UsedRange to be reset
    .Cells(1, .Columns.Count).EntireColumn.Delete
End With
'Save to workbook to commit the reset UsedRange
If Not ActiveWorkbook.ReadOnly Then
    ActiveWorkbook.Save 'assumes workbook has been saved previously.
End If
End Sub

Answer 2

您可以使用 Columns(x).ColumnWidth 来计算（如果列包含数据）。有关更详细的解决方案，请参阅 http://EzineArticles.com/7305778。