避免对周期性数据的不连续性进行插值

Question

我有一个复数值数据文件，我想在平面 pm3d 图中将相位信息与绝对值分开绘制。我像这样在-pi 和pi 之间定义了一个循环调色板

set palette model HSV
set palette define (-pi 0 1 1, pi 1 1 1)
set palette maxcolors 1000

即我将 HSV 色轮边缘的两个“红色”分配给相位域 (±pi) 的端点。然后我开始像这样绘制数据：

set pm3d map
set cbrange [-pi:pi]
splot 'datafile' w pm3d

结果如下所示：

如您所见，在相位值从 -pi 跳到 pi 的地方存在伪影，因为绘图算法会插入两个相反的值，从而产生接近 0（青色）的颜色。有没有办法从 gnuplot 中避免这个工件？当然，我总是可以以一种避免不连续性并在标准[-pi:pi] 域之外分配阶段的方式来操作数据，但我宁愿不这样做。

---

编辑： 您可以使用函数而不是数据文件来重现与上述类似的图：

I = {0,1}
set xrange [0:3]
set yrange [0:3]
set isosample 100
splot arg(exp(I*x*y)) w pm3d

Answer 1

我坚持在我的 cmets 中，通常最好尽可能使用 with image 绘制彩色地图，特别是因为对于矢量图像终端，pm3d 的（非）压缩会导致非常大图像尺寸。但是，您有一个非常具体的情况，因为您需要插值。我已经探索了set pm3d corners2color 的不同选项，它决定了相邻网格站点之间的插值是如何完成的。有些选项可能会解决您的问题，请自行判断：

set palette model HSV
set palette define (-pi 0 1 1, pi 1 1 1)
set palette maxcolors 1000
set pm3d map
set cbrange [-pi:pi]
I = {0,1}
set xrange [0:3]
set yrange [0:3]
set isosample 100

unset tics
unset colorbox

set term pngcairo size 640,4096; set output "out.png"
set multiplot layout 9,1

do for [mode in "mean geomean median min max c1 c2 c3 c4"] {

eval "set pm3d corners2color ".mode

set title mode            
splot arg(exp(I*x*y)) w pm3d not

}