如何编写忽略某些字段的 Data.Data 实例？

Question

我有以下数据类型：

data My a = Constr a Int String Float VariousComplexTypes ...

我希望能够在其上调用 over template (+1) 以更改此数据类型中的所有 Int 字段并在以后更改。但是，我不能请求 a 成为 Data 的实例（它的构造函数是隐藏的）。同时，我对用over template 调用更改它并不感兴趣，所以我尝试手动编写instance Data (My a)，使其忽略a 类型的第一个字段，但失败了。以下代码

instance Data (My a) where
  gunfold k z _ = k (k (k (z Constr)))
  toConstr _ = con
  dataTypeOf _ = ty

con = mkConstr ty "Constr" [] Prefix
ty = mkDataType "Mod.My" [con]

产生以下错误：

• No instance for (Data a) arising from a use of ‘k’
• In the first argument of ‘k’, namely ‘(k (z Constr))’
  In the first argument of ‘k’, namely ‘(k (k (z Constr)))’
  In the expression: k (k (k (z Constr)))
   |
61 |   gunfold k z _ = k (k (k (z Constr)))

这可能吗？除了手工编写所有样板文件外，我还有什么其他选择？

Answer 1

你可能会逃脱：

instance Typeable a => Data (My a) where
  gfoldl k z (Constr a x1 x2 x3)
    = z (Constr a) `k` x1 `k` x2 `k` x3
  gunfold k z _ = k . k . k . z $ Constr undefined
  toConstr _ = con
  dataTypeOf _ = ty
con = mkConstr ty "Constr" [] Prefix
ty = mkDataType "Mod.My" [con]

允许：

> gmapT (mkT ((+1) :: Int -> Int)) $ Constr ["list","of","strings"] 10 "foo" 18.0
Constr ["list","of","strings"] 11 "foo" 18.0
> gmapT (mkT ((+1) :: Int -> Int)) $ Constr (123 :: Int) 10 "foo" 18.0
Constr 123 11 "foo" 18.0    -- note: 123 passes through

如果违规类型 a 不是第一个构造函数参数，请参阅下面的变体。

请注意，gunfold 几乎不重要。请参阅 fromConstr 和 fromConstrB 了解它的使用方式。在这里，undefined 并不比 fromConstr 已经做的差。

真正重要的是gfoldl。 （请注意，即使在最小定义中不需要它，默认实现对于您实际想要操作的具有内部结构的数据类型也是无用的，因此您应该为所有非平凡的数据结构自己定义它。 ) 在这里，我刚刚编写了a 参数通过折叠传递，让其余的由k 函数处理。

如果a 类型不是第一个构造函数参数，或者您有多个这样的类型要不加改动地通过，您将需要更通用的东西，例如：

data My a b = Constr Int a String b Double deriving (Show)
instance (Typeable a, Typeable b) => Data (My a b) where
  gfoldl k z (Constr x1 a x2 b x3)
    = z go `k` x1 `k` x2 `k` x3
    where go y1 y2 y3 = Constr y1 a y2 b y3
  gunfold k z _ = k . k . k . z $ go
    where go y1 y2 y3 = Constr y1 undefined y2 undefined y3
  toConstr _ = con
  dataTypeOf _ = ty
con = mkConstr ty "Constr" [] Prefix
ty = mkDataType "Mod.My" [con]

给予：

> gmapT (mkT ((+1) :: Int -> Int)) $ Constr 10 (123 :: Int) "thing" [1,2,3] 3.1415
Constr 11 123 "thing" [1,2,3] 3.1415