无效的记录选择器和类型类

Question

我有一个类Movable 和多个数据类型实例化这个类。我想为所有这些类创建一个通用移动函数，如下所示，但显然我的记录语法不正确，因为我收到以下错误：

src\Controller.hs:24:13: error:
    * `position' is not a record selector
    * In the expression: o {position = (x', y')}
      In an equation for `move':
          move o
            = o {position = (x', y')}
            where
                (x, y) = position o
                (vx, vy) = velocity o
                x' = x + vx
                y' = y + vy
   |
24 | move o = o {position = (x', y')}
   |             ^^^^^^^^

我尝试应用此StackOverflow answer，但没有成功。 如何解决这个问题？或者除了使用记录语法还有其他方法可以解决这个问题吗？ 在这里你可以看到我的代码：

type Position = (Float, Float)
type Velocity = (Float, Float)

class Movable m where
    position :: m -> Position
    velocity :: m -> Velocity

data Player = Player { 
                playerBulletType :: Bullet,
                playerHealth :: Health,
                playerMaxVelocity :: MaxVelocity,
                playerVelocity :: Velocity,
                playerPosition :: Position,
                playerSprite :: Sprite
              }

instance Movable Player where
    position = playerPosition
    velocity = playerVelocity

move :: Movable o => o -> o
move o = o {position = (x', y')}
  where (x, y) = position o
        (vx, vy) = velocity o
        x' = x + vx
        y' = y + vy

Answer 1

首先，作为we already recommended in the other question，您可能根本不应该使用任何类来解决这个问题，而应该只使用参数化记录。

一个类不像 OO 中它实际上定义了一个数据结构。它只是定义了一些可能使用实例类型的值来给你一些东西的操作，但这只是一个特例。这些值也可以即时计算，通常没有办法将它们设置为另一个值。如果你需要，那么这样的“getter 方法”是不够的，你还需要一个“setter”。在现代 Haskell 中惯用的做法是，您可以一次性完成这两件事：getter 和 setter 的组合称为 lens。

import Control.Lens

class Movable m where
  position :: Lens' m Position
  velocity :: Lens' m Velocity

instance Movable Player where
  position f plyr = fmap (\p -> plyr{playerPosition=p}) . f $ playerPosition plyr
  velocity f plyr = fmap (\v -> plyr{playerVelocity=v}) . f $ playerVelocity plyr

那你就可以写了

move :: Movable o => o -> o
move o = o & position .~ (x', y')
  where (x, y) = o ^. position
        (vx, vy) = o ^. velocity
        x' = x + vx
        y' = y + vy

或者，更短的vector-space，

import Data.AffineSpace

move :: Movable o => o -> o
move o = o & position %~ (.+^ o^.velocity)