使用批处理文件验证用户给出的日期

Question

使用批处理文件，我从用户那里获取日期。 现在，我想验证日期是否为 YYYY-MM-DD 格式。

我一直在搜索，但我在这里没有得到一些东西： 在某处找到了这个：

set /p startDate=Start Date [YYYY-MM-DD]: 
if "%startDate:~2,1%%startDate:~5,1%" neq "--" goto invalidDate
for /f "tokens=2 delims==" %%I in ("%startDate%") do set datetime=%%I
ver > NUL
set /A month=1%MM%-100, day=1%DD%-100, year=1%YYYY%-10000, leap=year%%4
if errorlevel 1 goto invalidDate
if not defined dpm[%month%] goto invalidDate
if %leap% equ 0 set dpm[2]=29
if %day% gtr !dpm[%month%]! goto invalidDate
if %day% lss 1 goto invalidDate
echo Date correct: %YYYY%-%MM%-%DD%

这些是什么： 〜2， 1%%变量：~5, %%, 在 cmd 帮助中，我找到了单 % 但不是双 %%

还有，

set /A month=1%MM%-100, day=1%DD%-100, year=1%YYYY%-10000, leap=year%%4

这实际上在做什么。谁能逐个解释一下？

Answer 1

有时会使用双 %（尽管我不知道确切的目的；我认为这是为了延迟扩展）但在您的情况下，它只是使用的两个变量的连接：

set foo=foo
set bar=bar
echo %foo%%bar%

->foobar

它的另一个用途（至少在批处理文件中）是在 for 循环中声明和使用变量：for /l %%I in(1,1,5) do echo %%i。在命令提示符下，您只会写 %i。
说实话，您发布的第二行对我来说毫无意义... 感谢 Aacinis 的评论，现在这对我来说很有意义！基本上完成的是：

变量是 set 和 /Arithmetic 项，其中 1 被添加到前面以再次减去它。示例：

set /a year=1%YYYY%-10000

-> 将变量 year 的值设置为变量 1YYYY - 10000 的值。这样做（感谢 Aacini 再次解释）以防止带有前导零（例如 08）的输入被解释为在这种情况下会导致无效日期的八进制值。请注意，是否使用/a 会有所不同：

set foo=1+1
set /a bar=1+1
echo foo %foo%
echo bar %bar%

接下来我们有另一个 %% 的情况，在这种情况下是模运算符。

如果您愿意，模运算符将返回除法的其余部分。例子：

10 %% 2 = 0（您可以将 10 除以 2 而无需任何余数）
11 %% 4 = 3（因为 8 乘 4 为 2，其余 8 到 11 为 3）

无论年份是闰年（值 == 0）还是不是（值！= 0），都会保存变量leap。然而，这在检查闰年时必须考虑的其他规则有点容易，但不属于这里......

%startDate:~2,1%%startDate:~5,1%

将生成一个字符串，该字符串在第一个 2 之后采用 1 字符，在第一个 5 之后采用 1 > 字符。在您的情况下，您必须将其更改为 ~4,1 和 ~7,1，因为第 5 和第 8 个字符是程序检查的破折号。

J.Baoby 建议this link 仔细看看。另外两个重要的帮助来源是 Dostips 和 SS64。

欢迎提问:)

Answer 2

您的程序肯定有一些代码问题，但我将为您提供一个替代方法来检查使用一点XCOPY 诡计的有效日期。它基本上使用 XCOPY 检查两个空文件夹以进行复制，但我们使用 /L 选项，这样它实际上不会复制任何内容。另一个技巧是，如果日期无效，它会在尝试复制之前抛出错误，我们可以使用它来重定向回问题以询问有效日期。

@echo off

:invalidDate
cls
set /p startDate=Start Date YYYY-MM-DD:

REM xcopy needs date in m-d-y format
for /f "tokens=1,2,3 delims=-" %%G in ("%startDate%") do set checkdate=%%H-%%I-%%G
set rand=%random%
md "dummy%rand%\empty%rand%"

xcopy /d:%checkdate% /t "dummy%rand%\empty%rand%" "dummy%rand%" >nul 2>&1 ||(
    rd /s /q "dummy%rand%" 
    goto invalidDate
    )

rd /s /q "dummy%rand%"
echo %startdate% is a valid date

pause

Answer 3

好吧，如果你拿一个工作代码，修改它然后你问“为什么这个代码不起作用？”，我认为答案是显而易见的......

这是你“在某处找到”的original code：

@echo off
setlocal EnableDelayedExpansion

set i=0
for %%a in (31 28 31 30 31 30 31 31 30 31 30 31) do (
   set /A i+=1
   set dpm[!i!]=%%a
)

set /P "inDate=Please insert date (MM-DD-YYYY format): "
if "%inDate:~2,1%%inDate:~5,1%" neq "--" goto invalidDate
for /F "tokens=1-3 delims=-" %%a in ("%inDate%") do set "MM=%%a" & set "DD=%%b" & set "YYYY=%%c"
ver > NUL
set /A month=1%MM%-100, day=1%DD%-100, year=1%YYYY%-10000, leap=year%%4  2>NUL
if errorlevel 1 goto invalidDate
if not defined dpm[%month%] goto invalidDate
if %leap% equ 0 set dpm[2]=29
if %day% gtr !dpm[%month%]! goto invalidDate
if %day% lss 1 goto invalidDate
echo Date correct: %YYYY%-%MM%-%DD%
goto :EOF

:invalidDate
echo Bad date

如果要将原来的 MM-DD-YYYY 日期格式更改为 YYYY-MM-DD，则必须更改以下几行：

set /P "inDate=Please insert date (MM-DD-YYYY format): "
if "%inDate:~2,1%%inDate:~5,1%" neq "--" goto invalidDate
for /F "tokens=1-3 delims=-" %%a in ("%inDate%") do set "MM=%%a" & set "DD=%%b" & set "YYYY=%%c"

...由这些人：

set /P "startDate=Start Date [YYYY-MM-DD]: "
if "%startDate:~4,1%%startDate:~7,1%" neq "--" goto invalidDate
for /F "tokens=1-3 delims=-" %%a in ("%startDate%") do set "YYYY=%%a" & set "MM=%%b" & set "DD=%%c"

!dpm[%month%]! 部分的进一步解释见this answer。我邀请您阅读这样的答案并点赞它，因为它只需要几个点赞即可达到 100！ ;)