MS Word VBA 样式和分页清理

Question

我公司的工作流程目前包括一个流程，我们从存储库中导出文档，稍微清理一下，然后将其发送到下线以供审核/批准。 “稍微清理一下”涉及运行一个宏，该宏除其他外，对样式进行查找/替换，以将它们从存储库中的内容更改为我们的文档模板指定的内容。因此，例如，存储库为我们提供了“p_body”的样式，我们需要它是“body”。这个宏工作得很好，除了一些我想看看我们是否可以完善的东西。

第一个问题是，当涉及到它提供的样式时，存储库的行为往往有些不可预测。要使用上面的示例，不是以该样式标记所有“p_body”文本，而是返回“p_body”、“p_body_1”、“p_body_1_1”等。目前，宏中的样式切换都是硬编码的，所以要让宏修复某些东西，它必须知道它的存在。因此，如果存储库吐出一种不在宏中的样式，它就不会得到修复。我知道，如果我正在处理 HTML 文档，我可以使用正则表达式来查找“p_body”样式的所有版本，并将它们替换为“body”。有没有办法使用这种更智能的查找/替换版本，而不是对每个需要替换的样式进行硬编码？

第二个问题需要一个单独的问题来解决，所以现在被删掉了。

对于后代，以下是宏查找/替换块之一的样子：

Selection.Find.ClearFormatting
Selection.Find.Style = ActiveDocument.Styles("p_body")
Selection.Find.Replacement.ClearFormatting
Selection.Find.Replacement.Style = ActiveDocument.Styles("body")
With Selection.Find
    .Text = ""
    .Replacement.Text = ""
    .Forward = True
    .Wrap = wdFindAsk
    .Format = True
    .MatchCase = False
    .MatchWholeWord = False
    .MatchWildcards = False
    .MatchSoundsLike = False
    .MatchAllWordForms = False
End With
Selection.Find.Execute Replace:=wdReplaceAll

Answer 1

为了处理 p_body 和其他人的样式名称变化，试试这个。您用要查找的名称填充 StyName1 数组，并在 StyName2 数组中放置替换名称。这必须是一对一的比赛。

这只是编码它的众多方法之一。

Sub StyleNames()
    Dim StyName1 As Variant, StyName2 As Variant
    StyName1 = Array("p_body", "p_bold")
    StyName2 = Array("body", "bold")
    
    Dim i As Long
    Dim findStyName As String, replaceName As String
    
    For i = LBound(StyName1) To UBound(StyName1)
        findStyName = StyName1(i)
        replaceName = StyName2(i)
        FindAndReplaceStyles findStyName, replaceName
    Next
    
End Sub

Private Function FindAndReplaceStyles(ByRef findStyName As String, ByRef replaceName As String)
    Dim sty As Word.Style, aStory As Word.Range
    For Each sty In ActiveDocument.Styles
        If InStr(1, sty.NameLocal, findStyName) Then
            For Each aStory In ActiveDocument.StoryRanges
                With aStory.Find
                    .ClearFormatting
                    .Format = True
                    .Forward = True
                    .MatchWildcards = False
                    .Style = sty.NameLocal
                    .Text = ""
                    .Wrap = wdFindStop
                    .Replacement.ClearFormatting
                    .Replacement.Style = replaceName
                    .Replacement.Text = ""
                    .Execute Replace:=Word.wdReplaceAll
                End With
            Next
            Exit For
        End If
    Next
End Function