在工作簿之间切换

Question

我有一个代码在另一个工作簿中搜索特定信息，但该工作簿更改了名称和格式。我目前正在使用 workbook.open 打开它，当我指定文件位置时，它具有动态部分（您将了解示例代码）。问题是在代码中间我需要回到第一个工作簿（运行代码的那个），做一些事情，然后再回到它搜索信息的工作簿。我尝试使用 dim secondfile 作为字符串/工作簿将其设置为变量（两者都尝试过），然后尝试在它“活动”时将其设置为活动工作簿，这样我可以稍后在需要时使用“secondfile.activate”回去吧，但没有运气。代码如下：

dim originalworkbook as workbook
set originalworkbook as this workbook
dim wb as workbook
set wb as Workbooks.Open("C:\Users\abc\Documents\bla bla bla " + Range("D6").Offset(iLoop).Value)
'code here...
originalworkbook.activate
'code here...
'[insert code here to go back to the wb workbook]

我不能让它再次打开 wb 工作簿，因为它没有意义。现在我有 1k+ 数据的列表，这些数据在另外 30 多个文件中搜索。文件的名称在第一个工作簿上，至少是其中的一部分，正如您在代码中看到的那样。我使用 "Range("D6").offset" 部分来获取它。问题是，如果我每次都关闭并打开第二个工作簿，运行代码将花费太长时间，所以我想做的是搜索特定文件中的所有内容，并在搜索完所有内容后，保存并关闭它。这就是为什么我需要回到这个文件......

PS：并非所有文件的格式都相同，这就是为什么我没有使用“workbooks.activate”或类似的东西，然后使用相同的“Range(“D6”).offset”来设置文件激活，因为有些在 .xls 中，有些在 xlsx...

Answer 1

Public w as workbook    
For Each w In Workbooks
        If w.Name = originalworkbook Then
            Workbooks(w.Name).Activate
            'Do Stuff
        Exit For
        End If
Next w

上面的美妙之处在于，您可以使用它来同时打开无数个 excel 文件。只需将If w.Name = original workbook then 更改为if w.Name like "*charcters from a file name*" then

通配符可让您高效搜索

希望这会有所帮助！

Answer 2

由于您的代码确实不是很具有描述性，因此我将给您一段我的代码，并尝试解释发生了什么。我正在用这段代码写在另一个工作簿中，从第一个开始放置信息。这是一个很长的子，我会删除不必要的部分。

我试图涵盖你会遇到的所有情况。

sub TemplateFiller(AHNSnumber as String)
    Dim wbk As Workbook
    Dim wbpath As String
    Dim lastline as long
    Dim wbName as string

    wbpath = "O:\08_Lean_Eng\10_On_going\David\Soldier's Pond\MDR\Templates\TemplateCustom.xls"

    'This is to check if it's open first. Only open it if it is closed!
    'IsWorkBookOpen is one of my own functions, not included here
    If IsWorkBookOpen(wbpath) = False Then
        Set wbk = Workbooks.Open(wbpath) 'Notice: set wbk =, not Set wbk as
    ElseIf IsWorkBookOpen(wbpath) = True Then
        wbName = "somethingworkbook.xlsb"
        Set wbk = Workbooks(wbName)
    End If

    'Finding the last line in the other wbk (I'm using info from the other wbk for variables here)
    lastline = wbk.Sheets("DL001").Range("BG65000").End(xlUp).row + 1

    wbk.Sheets("Dl001").Range("F" & lastline) = AHNSnumber 'Using a passed variable
    wbk.Sheets("Dl001").Range("G" & lastline) = "OK" 'Writing some stuff
    wbk.Sheets("Dl001").Range("H" & lastline) = ThisWorkbook.Sheets("a").Range("A1") 'Value from one to the other and vice versa
    Thisworkbook.sheets("b").Range("A2") = wbk.Sheets("Dl001").Range("A" & lastline)


    'Changing a variable in this workbook
    ThisWorkbook.Sheets("Data").Range("Revision") = ThisWorkbook.Sheets("Data").Range("Revision") + 1

End sub

'I am not the original writer of this function.
Function IsWorkBookOpen(filename As String) As Boolean
    Dim ff As Long, ErrNo As Long

    On Error Resume Next
    ff = FreeFile()
    Open filename For Input Lock Read As #ff
    Close ff
    ErrNo = Err
    On Error GoTo 0

    Select Case ErrNo
    Case 0:    IsWorkBookOpen = False
    Case 70:   IsWorkBookOpen = True
    Case Else: Error ErrNo
    End Select
End Function