如何将我的宏更改为 Worksheet_Change 事件 Excel VBA

Question

我有一个在工作簿关闭时调用的宏。它检查不同工作表上两个表中的列，并根据找到的内容分配行号。

Worksheet_Change 处理程序位于具有Projects 范围的工作表上。 Database 范围位于同一工作簿的另一个工作表上。

每当我在其他任何地方调用宏时，它要么生成错误，要么导致 excel 部分冻结的常见错误（任何人都知道这是什么鬼？！？！？！）。

无论如何，我放弃之前的最后手段是将宏更改为工作表更改事件，我想知道是否可以在创建此事件时获得一些帮助。
原宏：

Sub FindRow()
'This module verifies row numbers in the database by matching them to the opportunities in the Projects
'worksheet. It then assigns row numbers in the Projects worksheet.

    Application.ScreenUpdating = False
    Dim LastRow As Long

    LastRow = Application.ThisWorkbook.Sheets("Projects").Cells.Find("*", SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row

    Dim rng As Range
    Dim foundRng As Range
    For Each rng In Sheets("Projects").Range("B2:B" & LastRow)
        Set foundRng = Sheets("Database").Range("C:C").Find(rng, LookIn:=xlValues, lookat:=xlWhole)
        If Not foundRng Is Nothing Then
            rng.Offset(0, -1) = foundRng.Row
        End If
    Next rng
    Application.ScreenUpdating = True
End Sub

我提议的更改：

 Public Sub Worksheet_Change(ByVal Target As Range)
     Dim Records As Range

        Set Records = Range("Records")
        If Not Application.Intersect(Records, Range(Target.Address)) Is Nothing Then
        Application.ScreenUpdating = False
        Dim LastRow As Long    
        LastRow = Application.ThisWorkbook.Sheets("Projects").Cells.Find("*", SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row

        Dim rng As Range
        Dim foundRng As Range
        For Each rng In Sheets("Projects").Range("B2:B" & LastRow)
            Set foundRng = Sheets("Database").Range("C:C").Find(rng, LookIn:=xlValues, lookat:=xlWhole)
            If Not foundRng Is Nothing Then
                rng.Offset(0, -1) = foundRng.Row
            End If
        Next rng
        Application.ScreenUpdating = True
End If
    End Sub

但是，我在定义变量 LastRow 的行上不断收到错误消息。
即使之前所有内容都已正确定义，我也会收到应用程序定义的错误。

提前致谢。

Answer 1

Worksheet_Change 句柄位于具有Projects 范围的工作表上。数据库范围位于同一工作簿中的另一个工作表上。 – 雷米 1 分钟前

这意味着rng 也在Projects 表上：

For Each rng In Sheets("Projects").Range("B2:B" & LastRow)

（顺便说一句，Me.Range("B2:B" & LastRow) 在这里就不会那么模棱两可了）

您正在处理Projects 工作表上的Worksheet_Change 事件，只要Projects 工作表上的单元格值发生更改，Excel 就会触发该事件。然后在那个处理程序中，你这样做：

rng.Offset(0, -1) = foundRng.Row

rng 是 Projects 工作表上的一个范围，您正在进入工作表更改的递归循环， 很可能是导致代码崩溃的原因。

当您进行工作表更改同时处理工作表更改时，您需要告诉 Excel“没关系，我知道了”，方法是防止它每次都重新触发 Worksheet.Change 事件：

Application.EnableEvents = False

'...code...

Application.EnableEvents = True

此外，当您切换 Application.ScreenUpdating = False 时，您是在告诉 Excel“在我这么说之前不要重新绘制自己”——这在很多情况下可以大大加快速度，但这也意味着您需要切换如果发生不好的事情，它会手动重新启动。

您可以通过实现错误处理程序来避免这种情况 - 原则如下：

Sub DoSomething()
    On Error GoTo CleanFail
    Application.EnableEvents = False
    Application.ScreenUpdating = False

    '...code...

CleanExit:
    Application.EnableEvents = True
    Application.ScreenUpdating = True
    Exit Sub
CleanFail:
    Debug.Print Err.Description
    Stop
    Resume CleanExit
    Resume 'F8 takes you to the error-throwing statement
End Sub

Answer 2

您尚未指明哪个工作表是具有 worksheet_change 事件的活动工作表。

无论如何，这里有一个代码可以在 B 列“项目”中找到最后一行

    Dim LastRow As Long, sh As Worksheet

    Set sh = Sheets("Projects")

    LastRow = sh.Cells(sh.Rows.Count, "B").End(xlUp).Row
    MsgBox LastRow & " is the last row in Column B Sheet Projects!"