使用宏从 Excel 电子表格中删除任何非指定字符

Question

我正在尝试通过删除任何非标准字符来清理 Excel 中的 .CSV 文件。我关心的唯一字符是 A-Z、0-9 和一些标准的标点符号。任何其他字符，我想删除。

当我找到一个包含我未指定的任何字符的单元格时，我得到了以下宏来删除整行，但我不确定如何让它真正删除字符本身。

Sub Replace()
Dim sCharOK As String, s As String
Dim r As Range, rc As Range
Dim j As Long

sCharOK = "abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789, `~!@#$%^&*()_+-=[]\{}|;':"",./<>?™®"

Set r = Worksheets("features").UsedRange.SpecialCells(xlCellTypeConstants, xlTextValues)

' loop through all the cells with text constant values and deletes the rows with characters not in sCharOK
For Each rc In r
    s = rc.Value
    For j = 1 To Len(s)
        If InStr(sCharOK, Mid(s, j, 1)) = 0 Then
            rc.EntireRow.Delete
            Exit For
        End If
    Next j
Next rc

End Sub

我认为有一种相当简单的方法可以使这段代码适应那个函数，但我对 VBA 不够熟悉，无法真正知道如何去做。非常感谢任何见解！

Answer 1

另一种方式是Range.Replace，例如：

Sub test()
  Dim sCharOK As String
  sCharOK = "abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789, `~!@#$%^&*()_+-=[]\{}|;':"",./<>?™®" & Chr(1)
  Dim i As Long
  For i = 0 To 255
    If InStr(sCharOK, Chr(i)) = 0 Then
      ActiveSheet.Cells.Replace What:=Chr(i), Replacement:="", LookAt:=xlPart, MatchCase:=True, SearchFormat:=False, ReplaceFormat:=False
    End If
  Next
End Sub

编辑

如果只需要删除不可打印的字符，查看@ryguy72 的答案也提供了另一种方法（在问题中，µ²äöüßÉõ 之类的内容将被删除，但此代码不会）也假设没有公式 ：

Sub test()
  With ActiveSheet.UsedRange
    .Value = Evaluate("TRIM(CLEAN(" & .Address & "))")
  End With
End Sub

或者直接在即时窗口中运行这一行：

ActiveSheet.UsedRange.Value = Evaluate("TRIM(CLEAN(" & ActiveSheet.UsedRange.Address & "))")

Answer 2

您还可以使用正则表达式，从而避免在循环中检查每个字符。 （尽管正则表达式引擎必须这样做）。

下面解释的正则表达式模式包含您的字符列表，使用的字符类表示匹配未列出的所有内容。

如果速度成为问题，您可以使用 vba 数组来加快速度。

Option Explicit
Sub ReplaceNonStdChars()
    Const sPat As String = "[^\x20-\x7E\x99\xAE]"
    Dim RE As Object
    Dim R As Range, C As Range

Set R = Worksheets("features").UsedRange.SpecialCells(xlCellTypeConstants, xlTextValues)

Set RE = CreateObject("vbscript.regexp")
With RE
    .Global = True
    .Pattern = sPat
    For Each C In R
        C.Value = .Replace(C.Text, "")
    Next C
End With
End Sub

正则表达式说明

[^\x20-\x7E\x99\xAE]

[^\x20-\x7E\x99\xAE]

• Match any single character NOT present in the list below[^\x20-\x7E\x99\xAE]
  • A character in the range between these two characters\x20-\x7E
    • The character “ ” which occupies position 0x20 (32 decimal) in the character set\x20
    • The character “~” which occupies position 0x7E (126 decimal) in the character set\x7E
  • The character with position 0x99 (153 decimal) in the character set\x99
  • The character with position 0xAE (174 decimal) in the character set\xAE

使用RegexBuddy创建

Answer 3

如果是我，我会在每次找到无效字符时对原始字符串使用替换命令，将无效字符更改为 null。然后将原始单元格值替换为修改后的字符串。像这样的...

一种可能的方法（已测试）

Sub RemoveInvalidCharacters()
Dim sCharOK As String, s As String
Dim r As Range, rc As Range
Dim j As Long
Dim badchar As Boolean

sCharOK = "abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789, `~!@#$%^&*()_+-=[]\{}|;':"",./<>?™®"

Set r = Worksheets("features").UsedRange.SpecialCells(xlCellTypeConstants, xlTextValues)

' loop through all the cells with text constant values and
' deletes the invalid characters not in sCharOK from each Value property
For Each rc In r
    badchar = False
    s = rc.Value
    For j = 1 To Len(s)
        If InStr(sCharOK, Mid(s, j, 1)) = 0 Then
            badchar = True
            s = Replace(s, Mid(s, j, 1), "")
        End If
    Next j
    If badchar Then
        rc.Value = s
    End If
Next rc

End Sub

Answer 4

从字面上看，我今天必须这样做。下面的脚本非常适合我。

Sub Clean_and_Trim_Cells()
    Application.ScreenUpdating = False
    Application.Calculation = xlCalculationManual
    Dim s As String
    For Each c In ActiveSheet.UsedRange
        s = c.Value
        If Trim(Application.Clean(s)) <> s Then
            s = Trim(Application.Clean(s))
            c.Value = s
        End If
    Next
    Application.ScreenUpdating = True
    Application.Calculation = xlCalculationAutomatic
End Sub