VBA - 遍历多个工作表并应用过滤器

Question

我需要对同一工作簿中的所有工作表应用相同的过滤器。

所有工作表在第一行都有标题，但应该应用过滤器的标题名称并不总是在同一列中，即工作表一个有问题的标题在工作表 2 的 H 列中它在 A 列中，在工作表 3 中它在 L 列中，依此类推......

此外，有些标题与标准不完全匹配 - 即，有些标题为“STATUS”，有些为“prefix_Status”，其他为“CurrentStatus”等等..所以我需要使用Instr 功能（除非有更好的选择）但我似乎无法弄清楚在哪里或如何使用它..

这是我目前的代码：

Sub WorksheetLoop()

         Dim WS_Count As Integer
         Dim I As Integer

         ' Set WS_Count equal to the number of worksheets in the active
         ' workbook.
         WS_Count = ActiveWorkbook.Worksheets.count

         ' Begin the loop.
         For I = 1 To WS_Count

            Dim count As Integer, rngData As Range
            Set rngData = Range("A1").CurrentRegion

            count = Application.WorksheetFunction.Match("STATUS", Range("A1:AZ1"), 0)

            rngData.autofilter Field:=count, Criteria1:="INACTIVE"

         Next I

End Sub

此代码仅将过滤器应用于一张纸。

Answer 1

只要您没有在代码中明确指定工作表，您总是指的是ActiveSheet。因此，在Range() 中，您必须像这样引用工作表：

发件人：

Set rngData = Range("A1").CurrentRegion
count = Application.WorksheetFunction.Match("STATUS", Range("A1:AZ1"), 0)

改为：

With Worksheets(I)
    Set rngData = .Range("A1").CurrentRegion
    count = Application.WorksheetFunction.Match("STATUS", .Range("A1:AZ1"), 0)
End With

With Worksheets(I) - End With 之间的代码中的点是不同之处：

---

关于Application.WorksheetFunction.Match，它只匹配包含完全单词“STATUS”的单元格。如果前面有空格或后面有符号，那么这样的做法是个好主意：

count = Application.Match("*STATUS*", Worksheets(1).Range("A1:AZ1"), 0)

那么仍然需要检查。像这样：

If Not IsError(count) Then
    rngData.autofilter Field:=count, Criteria1:="INACTIVE"
End If

---

关于问题的第二部分，在 Match 函数中的值周围使用*：

Public Sub TestMe()    
    Range("E1") = "5teSt34"
    Debug.Print Application.WorksheetFunction.Match("*Test*", Range("A1:H1"), 0)    
End Sub

将始终返回5。

Answer 2

基本上，您需要做的是在循环时引用代码中的工作表，而您并没有这样做 - 您只是通过不包含任何引用来引用活动工作表。

通过 Match，您可以使用通配符。

Sub WorksheetLoop()

Dim WS_Count As Long
Dim I As Long

WS_Count = ActiveWorkbook.Worksheets.count

Dim count As Variant, rngData As Range
For I = 1 To WS_Count
   Set rngData = Worksheets(I).Range("A1").CurrentRegion
   count = Application.Match("STATUS", Worksheets(I).Range("A1:AZ1"), 0)
   If IsNumeric(count) Then rngData.AutoFilter Field:=count, Criteria1:="INACTIVE"
Next I

End Sub