XSLT - 超链接基于其属性的 XML 元素

Question

我有以下存储电影和演员的 XML：

<movies
xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
xsi:noNamespaceSchemaLocation="movies.xsd">

<movie movieID="1">
    <cast>
        <actors>
            <actor actorID="1">
                <name>Bob</name>
            </actor>
            <actor actorID="2">
                <name>John</name>
            </actor>
            <actor>
                <name>Mike</name>
            </actor>
        </actors>
    </cast>
</movie>

</movies>

前两个演员有一个具有唯一值的属性“actorID”。第三个演员没有属性。 我想将前两个演员的名字显示为超链接并显示第三个演员 以纯文本形式命名。

这是我的 XSLT：

<xsl:template match="/">
    <xsl:apply-templates select="movies/movie" />
</xsl:template>

<xsl:template match="movie">    
    <xsl:text>Actors: </xsl:text>
    <xsl:apply-templates select="cast/actors/actor[@actorID]/name"/>
</xsl:template>

<xsl:template match="actor[@actorID]/name">
    <xsl:element name="a">
        <xsl:attribute name="href">www.mywebsite.com</xsl:attribute>
        <xsl:value-of select="." />
    </xsl:element>
    <xsl:element name="br" />
</xsl:template>

<xsl:template match="actor/name">
    <xsl:value-of select="." />
    <xsl:element name="br" />
</xsl:template>

我得到的输出是 Bob 和 John 显示为纯文本，而 Mike 根本没有显示。所以它的作用几乎相反 我想要达到的目标。

Answer 1

你的 XPath 在这里：

<xsl:apply-templates select="cast/actors/actor[@actorID]/name"/>

导致模板仅应用于具有actorID 属性的演员。相反，听起来这是您应该使用的：

<xsl:apply-templates select="cast/actors/actor/name"/>

那么 XSLT 的行为应该如您所愿。

附带说明，我建议在 XSLT 中使用文字元素，除非需要使用 xsl:element：

<xsl:template match="actor[@actorID]/name">
    <a href="http://www.mywebsite.com">
        <xsl:value-of select="." />
    </a>
    <br />
</xsl:template>

<xsl:template match="actor/name">
    <xsl:value-of select="." />
    <br />
</xsl:template>

恕我直言，它使 XSLT 更易于阅读。如果需要在属性中包含值，可以使用属性值模板：

<a href="http://www.mywebsite.com/actors?id={../@actorID}">