Clojure 中的 OAuth1

Question

我正在尝试使用 Clojure 与 API (Context.IO) 集成。 Context.IO 使用 OAuth 1，它需要通知消费者密钥和消费者秘密凭据以与之集成。

我过去曾使用请求库 (https://github.com/request/request) 设法将 Context.IO 与 Node.JS 一起使用。原来很简单，就是把consumer_key和consumer_secret填入一个对象，然后在请求中传入oauth参数。

var oauth   = 
{
  consumer_key: 'dsfdfssdf',
  consumer_secret: 'dasfsafdsf'
};

request.post( { url:url, oauth:oauth } )

现在我正在尝试使用 clj-oauth https://github.com/mattrepl/clj-oauth 完成相同的操作，但我有点迷茫，因为它需要的参数太不同（我猜对于更复杂的用例），而且我很难时间试图弄清楚如何做简单的事情。

要添加更多信息，Context IO 仅将 OAuth 用于 API 身份验证，而不是用户授权。因此，它不需要通知令牌，也不提供令牌。它只需要消费者密钥和签名（此处描述相同：dev.twitter.com/oauth/overview/creating-signatures）。

有人可以举一个类似于我在 Node 中使用 Clojure 或 clj-oauth（或任何其他库）完成的示例吗？我还没有找到这样做的方法。

谢谢！

Answer 1

我注册了 context io 来尝试一下。首先，在 leiningen 我设置了

:dependencies [[org.clojure/clojure "1.6.0"]
                 [clj-oauth "1.5.2"]
                 [clj-http "1.1.2"]] 

作为我的依赖项。下面有两个例子。一个调用不带任何参数的url，另一个调用相同的url，但带参数。

(ns scratch.core
  (:require [oauth.client :as oauth]
            [clj-http.client :as http]))

(def okey "key")

(def osecret "secret")

(def consumer (oauth/make-consumer okey
                                   osecret
                                   nil
                                   nil
                                   nil
                                   :hmac-sha1))

(defn test-get []
  (let [credentials (oauth/credentials consumer
                                       nil
                                       nil
                                       :GET
                                       "https://api.context.io/lite/users")]
    (http/get "https://api.context.io/lite/users" {:query-params credentials})))

(defn test-get-params []
  (let [params {:email "blah@blah.com"}
        credentials (oauth/credentials consumer
                                       nil
                                       nil
                                       :GET
                                       "https://api.context.io/lite/users"
                                       params)]
    (http/get "https://api.context.io/lite/users" {:query-params (merge credentials params)})))