Oracle 包中的全局变量大小

Question

如何根据函数的参数大小为oracle包中Varchar2类型的全局变量设置大小。

CREATE OR REPLACE PACKAGE Test 
AS

   g_lastname Varchar2(15);
   FUNCTION search( p_lastname IN varchar2);

END;

CREATE OR REPLACE PACKAGE BODY Test
AS
    FUNCTION search(p_lastname IN VARCHAR2) return VARCHAR2 
    IS
    BEGIN
        g_lastname := p_lastname;
        return g_lastname;
    END;
END;

这里的问题是如果 p_lastname 的大小超过 15 就会出错。

Answer 1

您不能，因为函数参数可以是varchar2 的任意大小，并且直到运行时才知道。

如果您知道稍后将如何使用该值，那么您可以根据表格列对其进行约束；因此，如果它最终将用于从表people 中选择，您可以将其声明为：

    g_lastname people.last_name%type;

您也可以在函数声明中使用该语法：

    FUNCTION search(p_lastname IN people.last_name%type) return VARCHAR2

...虽然这实际上并没有限制可以传入的值的大小；如果p_lastname 的值太大，分配仍然会失败。可以说，在这种情况下，它必须在某个时候失败，在这里它可能比你稍后在select 中尝试使用它时更好。但它在代码中提供了一些一致性，并且 (IMO) 显示了全局和参数的意图，这对于以后的维护和故障排除很有用。

如果您只是想避免错误，如果传递的值太长，您可以选择截断：

        g_lastname := substr(p_lastname, 1, 15);

... 或先测试长度，但幻数并不完全理想（如果您更改 g_lastname 的定义，您必须记住查找和替换任何依赖该长度的内容）；或者捕获并处理异常。

否则，仅仅声明它比你想象的要大并没有太大的缺点，最多：

    g_lastname varchar2(32767);

虽然您可能会想出一个实际的更小的最大长度，但该值将永远需要（当然，除非有人更改要求！）。 documentation 讨论大变量的内存分配。

Answer 2

"%type 对我的情况没有帮助。"

这很不寻常。大多数在 PL/SQL 程序之间传递的数据来自或最终出现在数据库表中。所以最佳实践是通过引用适当列的声明来定义变量和参数。

但是，对于真正不映射到任何表列的数据项，存在子类型声明。您可以在任何地方定义这些，但将所有声明组织在一个地方会很有帮助：

create or replace package types as
    subtype name_t is varchar2(15);
end;
/

您可以像这样在您的程序中使用它：

CREATE OR REPLACE PACKAGE Test 
AS

   FUNCTION search( p_lastname IN types.name_t) return types.name_t;

END;

（我将 g_lastname 从规范移至正文，因为将包变量封装在正文中并仅通过打包过程访问它们是个好主意。）

CREATE OR REPLACE PACKAGE BODY Test
AS

    g_lastname types.name_t;

    FUNCTION search( p_lastname IN types.name_t) return types.name_t 
    IS
    BEGIN
        g_lastname := p_lastname;
        return g_lastname;
    END;
END;

使用子类型的好处是只有一个地方可以定义类型的精度。如果您需要 20 个字符的名称，只需更改该包规范中的声明，更改就会传播到所有引用程序。