elixir String.split/3：如何判断匹配了哪个字符

Question

我正在尝试使用String.split/3 构建一个解析器作为练习，只是为了看看我是否可以使其比经典递归模式匹配更快（通过有效地分配更少的字符串），但我无法使其正确。

我需要能够在{ 或} 处将二进制文件分成两部分，而String.split(str, ["{", "}"], parts: 2) 当然可以做到这一点。我的问题是结果只包含列表[part1, part2]，但它不包含它匹配的字符，我需要它，因为它会影响解析器的行为。

我的第一直觉是自己制作index/2，但在阅读了更多内容后，seems 就像bad idea 一样

我的用例有更好的选择吗？我想尽可能少地遍历字符串，只在{ 和} 边界处创建新字符串。

感谢您的阅读！

Answer 1

由于您只想在第一次出现时拆分，我建议在这里使用:binary.match/3 和:binary.part/3。 :binary.match/3 返回匹配索引的元组和匹配成功的长度，然后可以与:binary.part/2 一起使用来拆分二进制文件。

defmodule A do
  def split(binary) do
    case :binary.match(binary, ["{", "}"]) do
      {start, length} ->
        before = :binary.part(binary, 0, start)
        match = :binary.part(binary, start, length)
        after_ = :binary.part(binary, start + length, byte_size(binary) - (start + length))
        {before, match, after_}
      :nomatch -> nil
    end
  end
end

IO.inspect A.split("foo { bar") |> IO.inspect
IO.inspect A.split("foo } bar") |> IO.inspect
IO.inspect A.split("foo + bar") |> IO.inspect

输出：

{"foo ", "{", " bar"}
{"foo ", "{", " bar"}
{"foo ", "}", " bar"}
{"foo ", "}", " bar"}
nil
nil

此实现仅在 :binary.match/3 调用中遍历字符串一次。使用的所有其他函数和操作都是O(1)。

我在我正在研究的 XML 解析器中使用了类似的方法，与二进制文件上的递​​归模式匹配相比，它提供了巨大的速度。

编辑：您可以使用模式匹配来使这段代码更短，而且我很确定与上面完全相同的性能：

defmodule A do
  def split(binary) do
    case :binary.match(binary, ["{", "}"]) do
      {start, length} ->
        <<a::binary-size(start), b::binary-size(length), c::binary>> = binary
        {a, b, c}
      :nomatch -> nil
    end
  end
end

Answer 2

深入挖掘String.split docs 并使用include_captures 选项。

iex> String.split("Foo{bar}", ~r({|}), [include_captures: true, trim: true])
["Foo", "{", "bar", "}"]